lnchr 0.2.2

A fuzzy terminal app launcher
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

{
  inputs = {
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixpkgs.url = "nixpkgs/nixos-unstable";
    crane.url = "github:ipetkov/crane";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      fenix,
      nixpkgs,
      crane,
      flake-utils,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

        fenixToolchain =
          with fenix.packages.${system};
          stable.withComponents [
            "cargo"
            "rustc"
            "rust-src"
          ];

        craneLib = (crane.mkLib pkgs).overrideToolchain fenixToolchain;

        lnchr = craneLib.buildPackage {
          src = craneLib.cleanCargoSource ./.;
          strictDeps = true;
          meta = {
            description = "A fuzzy terminal app launcher";
            homepage = "https://codeberg.org/paul-hartwich/lnchr";
            license = pkgs.lib.licenses.mit;
            mainProgram = "lnchr";
          };
        };
      in
      {
        packages = {
          default = lnchr;
          lnchr = lnchr;
        };

        apps.default = flake-utils.lib.mkApp { drv = lnchr; };

        devShells.default = craneLib.devShell {
          packages = with fenix.packages.${system}; [
            stable.clippy
            stable.rustfmt
            pkgs.rust-analyzer
          ];
        };
      }
    );
}