llama-cpp-sys-4 0.2.53

Low Level Bindings to llama.cpp
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153

#if defined(SRC_F16) || defined(DST_F16)
enable f16;
#endif

#ifdef SRC_F16
#define SRC_TYPE f16
#else
#define SRC_TYPE f32
#endif

#ifdef DST_F16
#define DST_TYPE f16
#else
#define DST_TYPE f32
#endif

struct Params {
    offset_src: u32, // in elements
    offset_dst: u32, // in elements

    // Strides (in elements)
    stride_src1: u32,
    stride_src2: u32,
    stride_src3: u32,

    stride_dst1: u32,
    stride_dst2: u32,
    stride_dst3: u32,

    // Shape of src/dst
    ne0: u32,
    ne1: u32,
    ne2: u32,
    ne3: u32,

    eps: f32
};

@group(0) @binding(0)
var<storage, read_write> src: array<SRC_TYPE>;

#ifdef INPLACE
@group(0) @binding(1)
var<uniform> params: Params;
#else
@group(0) @binding(1)
var<storage, read_write> dst: array<DST_TYPE>;

@group(0) @binding(2)
var<uniform> params: Params;
#endif

var<workgroup> scratch: array<f32, WG_SIZE * 2u>;

@compute @workgroup_size(WG_SIZE)
fn main(@builtin(workgroup_id) wid: vec3<u32>,
        @builtin(local_invocation_id) lid: vec3<u32>) {

    // one thread per row
    var i = wid.x;
    let i3 = i / (params.ne2 * params.ne1);
    i = i % (params.ne2 * params.ne1);
    let i2 = i / params.ne1;
    let i1 = i % params.ne1;
    let i_src_row = params.offset_src + i3 * params.stride_src3 + i2 * params.stride_src2 + i1 * params.stride_src1;
    let i_dst_row = params.offset_dst + i3 * params.stride_dst3 + i2 * params.stride_dst2 + i1 * params.stride_dst1;

    let elems = (params.ne0 + WG_SIZE - 1) / WG_SIZE;

    var sum = 0.0f;
    var col = lid.x;
    for (var j: u32 = 0; j < elems; j++) {
        if (col >= params.ne0) {
            break;
        }
        let v = f32(src[i_src_row + col]);
#ifdef NORM
        sum += v;
#else
        sum += v * v;
#endif
        col += WG_SIZE;
    }

    scratch[lid.x] = sum;
    workgroupBarrier();

    var offset: u32 = WG_SIZE / 2u;
    while (offset > 0) {
        if (lid.x < offset) {
            scratch[lid.x] += scratch[lid.x + offset];
        }
        offset /= 2u;
        workgroupBarrier();
    }
    sum = scratch[0];

#ifdef NORM
    let mean = sum / f32(params.ne0);
    var sq_sum = 0.0f;
    col = lid.x;
    for (var j: u32 = 0; j < elems; j++) {
        if (col >= params.ne0) {
            break;
        }
        let v = f32(src[i_src_row + col]);
        let d = v - mean;
        sq_sum += d * d;
        col += WG_SIZE;
    }

    workgroupBarrier();
    scratch[lid.x] = sq_sum;
    workgroupBarrier();
    offset = WG_SIZE / 2u;
    while (offset > 0) {
        if (lid.x < offset) {
            scratch[lid.x] += scratch[lid.x + offset];
        }
        offset /= 2u;
        workgroupBarrier();
    }

    let variance = scratch[0] / f32(params.ne0);
    let scale = 1.0 / sqrt(variance + params.eps);
#elif defined(RMS_NORM)
    let scale = 1.0/sqrt(sum/f32(params.ne0) + params.eps);
#elif defined(L2_NORM)
    let scale = 1.0/max(sqrt(sum), params.eps);
#endif

#ifdef NORM
    let mean_val = mean;
#else
    let mean_val = 0.0f;
#endif

    col = lid.x;
    for (var j: u32 = 0; j < elems; j++) {
        if (col >= params.ne0) {
            break;
        }
        let i_src = i_src_row + col;
        let i_dst = i_dst_row + col;
        let v = src[i_src];
#ifdef INPLACE
        src[i_dst] = scale * (v - mean_val);
#else
        dst[i_dst] = scale * (v - mean_val);
#endif
        col += WG_SIZE;
    }
}