linkcell 0.3.4

Periodic linked-cell k-nearest neighbour search for molecular simulations
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

@PACKAGE_INIT@

include(CMakeFindDependencyMacro)
find_dependency(Threads)

set_and_check(LINKCELL_INCLUDE_DIR "${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_INCLUDEDIR@")

if(WIN32)
  set_and_check(LINKCELL_LIBRARY "${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_BINDIR@/@LINKCELL_SHARED_NAME@")
  set_and_check(LINKCELL_IMPLIB "${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_LIBDIR@/@LINKCELL_IMPLIB_NAME@")
else()
  set_and_check(LINKCELL_LIBRARY "${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_LIBDIR@/@LINKCELL_SHARED_NAME@")
endif()

if(NOT TARGET linkcell::linkcell)
  add_library(linkcell::linkcell SHARED IMPORTED)
  set_target_properties(linkcell::linkcell PROPERTIES
    IMPORTED_LOCATION "${LINKCELL_LIBRARY}"
    INTERFACE_INCLUDE_DIRECTORIES "${LINKCELL_INCLUDE_DIR}")
  if(WIN32)
    set_target_properties(linkcell::linkcell PROPERTIES
      IMPORTED_IMPLIB "${LINKCELL_IMPLIB}")
  endif()
endif()

if(NOT TARGET linkcell::cpp)
  add_library(linkcell::cpp INTERFACE IMPORTED)
  set_target_properties(linkcell::cpp PROPERTIES
    INTERFACE_LINK_LIBRARIES linkcell::linkcell
    INTERFACE_COMPILE_FEATURES cxx_std_17)
endif()

if(@LINKCELL_WITH_GPULITE@ AND NOT TARGET linkcell::gpu)
  set_and_check(LINKCELL_GPU_LIBRARY
    "${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_LIBDIR@/@LINKCELL_GPU_STATIC_NAME@")
  add_library(linkcell::gpu STATIC IMPORTED)
  set_target_properties(linkcell::gpu PROPERTIES
    IMPORTED_LOCATION "${LINKCELL_GPU_LIBRARY}"
    INTERFACE_INCLUDE_DIRECTORIES "${LINKCELL_INCLUDE_DIR}"
    INTERFACE_COMPILE_DEFINITIONS LINKCELL_HAS_GPULITE=1
    INTERFACE_COMPILE_FEATURES cxx_std_17
    INTERFACE_LINK_LIBRARIES "linkcell::linkcell;@LINKCELL_GPU_SYSTEM_LIBS@")
endif()

check_required_components(linkcell)