libcorn 0.10.1

Parsing engine for Corn, a simple and pain-free configuration language.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93

WHITESPACE = _{ " " | "\t" | "\r" | "\n" }
COMMENT = _{ "//" ~ (!"\n" ~ ANY)* }

object = {
 "{" 
 ~ object_value* 
 ~ "}"
}

object_value = _{
  pair | spread
}

spread = {
  ".." ~ input
}

array = {
  "[" 
  ~ array_value* 
  ~ "]"
}

array_value = _{
  value | spread
}

pair = { path ~ "=" ~ value }

path = ${
  path_seg
  ~ ( "." ~ path_seg )*
}

path_seg = _{
    integer | quoted_path_seg | regular_path_seg
}

quoted_path_seg = ${ "'" ~ quoted_path_val ~ "'" }
quoted_path_val = ${ quoted_path_char + }
quoted_path_char = _{
	!("'" | "\\") ~ ANY
    | "\\" ~ "'"
}

regular_path_seg = ${ path_char + }

path_char = _{ !( WHITESPACE | "=" | "." ) ~ ANY }

value = _{ object | array | input | string | float | integer | boolean | null }

boolean = { "true" | "false" }
null = { "null" }

string = ${
  "\"" ~ string_val ~ "\""
}

string_val = ${ (input | char)* }

char = {
  !("\"" | "\\") ~ ANY
  | "\\" ~ ("\"" | "\\" | "n" | "r" | "t" | "$")
  | "\\" ~ ("u" ~ ASCII_HEX_DIGIT{4})
}

integer = ${
  hex_integer | decimal_integer
}

decimal_integer = @{
    "-"?
  ~ ("0" | ASCII_NONZERO_DIGIT ~ ("_"? ~ ASCII_DIGIT)*)
}

hex_integer = @{
    "0x" ~ ASCII_HEX_DIGIT+
}

float = @{
  "-"?
  ~ ("0" | ASCII_NONZERO_DIGIT ~ ASCII_DIGIT*)
  ~ ("." ~ ASCII_DIGIT*)
  ~ (^"e" ~ ("+" | "-")? ~ ASCII_DIGIT+)?
}

input = ${ !"\\" ~ "$" ~ (ASCII_ALPHA | "_") ~ (ASCII_ALPHANUMERIC | "_")+ }

assignment = { input ~ "=" ~ value }

assign_block = { "let" ~ "{" ~ assignment* ~ "}" ~ "in" }

config = _{ SOI ~ assign_block? ~ object ~ EOI }