lean-tui 1.1.0

Standalone TUI infoview for Lean 4 theorem prover
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74

{
  pkgs,
  crane,
  lean-tui,
}:
let
  inherit (pkgs) lib;

  nightlyWithTargets =
    targets: pkgs.rust-bin.selectLatestNightlyWith (toolchain: toolchain.default.override { inherit targets; });

  mkMuslPackage =
    arch:
    let
      target = "${arch}-unknown-linux-musl";
      muslPkgs =
        if arch == "x86_64" then pkgs.pkgsCross.musl64 else pkgs.pkgsCross.aarch64-multiplatform-musl;
      muslCrane = (crane.mkLib pkgs).overrideToolchain (_: nightlyWithTargets [ target ]);
      cc = "${muslPkgs.stdenv.cc}/bin/${muslPkgs.stdenv.cc.targetPrefix}cc";
      ar = "${muslPkgs.stdenv.cc.bintools}/bin/${muslPkgs.stdenv.cc.targetPrefix}ar";
      targetEnv = builtins.replaceStrings [ "-" ] [ "_" ] target;
      muslArgs = lean-tui.cargoArgs // {
        pname = "lean-tui-static";
        doCheck = false;
        CARGO_BUILD_TARGET = target;
        "CARGO_TARGET_${lib.toUpper targetEnv}_LINKER" = cc;
        "CC_${targetEnv}" = cc;
        "AR_${targetEnv}" = ar;
      };
    in
    muslCrane.buildPackage (muslArgs // { cargoArtifacts = muslCrane.buildDepsOnly muslArgs; });

  muslPackages = lib.genAttrs [ "x86_64" "aarch64" ] mkMuslPackage;

  writeNuTool =
    name: tools: script:
    pkgs.writers.writeNuBin name {
      makeWrapperArgs = [
        "--prefix"
        "PATH"
        ":"
        (lib.makeBinPath tools)
      ];
    } script;

  releasePlzOnCodeberg =
    subcommand:
    writeNuTool subcommand [
      (nightlyWithTargets [ ])
      pkgs.release-plz
      pkgs.gitMinimal
    ] "^release-plz ${subcommand} --forge gitea --git-token $env.CODEBERG_TOKEN";
in
{
  inherit muslPackages;

  dist = pkgs.runCommand "lean-tui-dist" { } (
    lib.concatLines (
      [ "mkdir -p $out" ]
      ++ lib.mapAttrsToList (
        arch: package:
        "tar -czf $out/lean-tui-${arch}-unknown-linux-musl.tar.gz -C ${package}/bin lean-tui"
      ) muslPackages
    )
  );

  release = releasePlzOnCodeberg "release";
  release-pr = releasePlzOnCodeberg "release-pr";
  cached-build = writeNuTool "cached-build" [ pkgs.cachix ] ./cached-build.nu;
  check-commits = writeNuTool "check-commits" [
    pkgs.convco
    pkgs.gitMinimal
  ] "def --wrapped main [...range: string] { ^convco check ...$range }";
}