lbug 0.20.0

An in-process property graph database management system built for query speed and scalability
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86

add_subdirectory(aggregate)
add_subdirectory(arithmetic)
add_subdirectory(array)
add_subdirectory(cast)
add_subdirectory(date)
add_subdirectory(gds)
add_subdirectory(list)
add_subdirectory(map)
add_subdirectory(path)
add_subdirectory(pattern)
add_subdirectory(sequence)
add_subdirectory(struct)
add_subdirectory(table)
add_subdirectory(union)
add_subdirectory(utility)
add_subdirectory(uuid)
add_subdirectory(string)
add_subdirectory(export)
add_subdirectory(internal_id)
add_subdirectory(timestamp)

set(LBUG_FUNCTION_SIMD_SOURCES simd_filter.cpp)
set(LBUG_BUILD_FILTER_AVX2 FALSE)
set(LBUG_BUILD_FILTER_NEON FALSE)
if(LBUG_ENABLE_SIMD AND NOT BUILD_WASM)
    if(OS_ARCH STREQUAL "amd64")
        if(MSVC)
            set(LBUG_BUILD_FILTER_AVX2 TRUE)
            set_source_files_properties(simd_filter_avx2.cpp PROPERTIES COMPILE_OPTIONS "/arch:AVX2")
        elseif(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
            include(CheckCXXCompilerFlag)
            check_cxx_compiler_flag("-mavx2" LBUG_COMPILER_SUPPORTS_MAVX2)
            if(LBUG_COMPILER_SUPPORTS_MAVX2)
                set(LBUG_BUILD_FILTER_AVX2 TRUE)
                set_source_files_properties(simd_filter_avx2.cpp PROPERTIES COMPILE_OPTIONS "-mavx2")
            endif()
        endif()
    elseif(OS_ARCH STREQUAL "arm64")
        if(MSVC OR CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
            set(LBUG_BUILD_FILTER_NEON TRUE)
        endif()
    endif()
endif()

if(LBUG_BUILD_FILTER_AVX2)
    list(APPEND LBUG_FUNCTION_SIMD_SOURCES simd_filter_avx2.cpp)
    set_source_files_properties(simd_filter.cpp
        PROPERTIES COMPILE_DEFINITIONS LBUG_SIMD_COMPILED_AVX2)
    message(STATUS "Query processor SIMD: AVX2 filter kernels enabled")
elseif(LBUG_BUILD_FILTER_NEON)
    list(APPEND LBUG_FUNCTION_SIMD_SOURCES simd_filter_neon.cpp)
    set_source_files_properties(simd_filter.cpp
        PROPERTIES COMPILE_DEFINITIONS LBUG_SIMD_COMPILED_NEON)
    message(STATUS "Query processor SIMD: NEON filter kernels enabled")
else()
    message(STATUS "Query processor SIMD: scalar filter path only")
endif()

add_library(lbug_function
        OBJECT
        aggregate_function.cpp
        base_lower_upper_operation.cpp
        built_in_function_utils.cpp
        cast_string_non_nested_functions.cpp
        cast_from_string_functions.cpp
        comparison_functions.cpp
        find_function.cpp
        function.cpp
        function_collection.cpp
        scalar_macro_function.cpp
        vector_arithmetic_functions.cpp
        vector_boolean_functions.cpp
        vector_cast_functions.cpp
        vector_date_functions.cpp
        vector_hash_functions.cpp
        vector_null_functions.cpp
        vector_node_rel_functions.cpp
        vector_string_functions.cpp
        vector_timestamp_functions.cpp
        vector_blob_functions.cpp
        vector_uuid_functions.cpp
        ${LBUG_FUNCTION_SIMD_SOURCES})

set(ALL_OBJECT_FILES
        ${ALL_OBJECT_FILES} $<TARGET_OBJECTS:lbug_function>
        PARENT_SCOPE)