korrosync 0.2.0

A KOReader Sync Server
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155

{
  description = "KOReader Sync Server";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-parts.url = "github:hercules-ci/flake-parts";

    git-hooks-nix = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = inputs @ {flake-parts, ...}:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = ["x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin"];

      imports = [
        inputs.git-hooks-nix.flakeModule
        inputs.treefmt-nix.flakeModule
      ];

      perSystem = let
        targets = [
          "aarch64-unknown-linux-gnu"
          "aarch64-unknown-linux-musl"

          "armv7-unknown-linux-gnueabihf"
          "armv7-unknown-linux-musleabihf"

          "x86_64-unknown-linux-gnu"
          "x86_64-unknown-linux-musl"

          "aarch64-apple-darwin"
          "x86_64-apple-darwin"

          "x86_64-pc-windows-gnu"
        ];
      in
        {
          config,
          system,
          ...
        }: let
          overlays = [(import inputs.rust-overlay)];
          pkgs = import inputs.nixpkgs {
            inherit system overlays;
          };

          rustToolchain = pkgs.rust-bin.stable.latest.default.override {
            extensions = [
              "rust-src"
              "rust-analyzer"
              "llvm-tools-preview"
            ];
            inherit targets;
          };

          buildInputs = with pkgs;
            [
              openssl
              pkg-config
            ]
            ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
              pkgs.darwin.apple_sdk.frameworks.Security
              pkgs.darwin.apple_sdk.frameworks.SystemConfiguration
            ];
        in {
          devShells.default = pkgs.mkShell {
            inherit buildInputs;
            nativeBuildInputs = with pkgs; [
              rustToolchain
              bacon
              cargo-edit
              cargo-machete
              cargo-zigbuild
              cargo-tarpaulin
              cargo-audit
              cargo-deny
              cargo-llvm-cov
              just

              zig
              grcov
            ];

            shellHook = ''
              ${config.pre-commit.installationScript}

              echo "Rust development environment loaded"
              echo "Rust version: $(rustc --version)"
              echo ""
              echo "Cross-compile with: cargo zigbuild --target <target>"
              echo ""
              echo -n "Available targets: ${pkgs.lib.strings.concatStringsSep ", " targets}"
              echo ""
            '';
          };

          packages = let
            cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
            mkRustPackage = toolchain:
              toolchain {
                pname = "${cargoToml.package.name}";
                inherit (cargoToml.package) version;

                src = pkgs.lib.cleanSource ./.;
                cargoLock.lockFile = ./Cargo.lock;

                inherit buildInputs;
                nativeBuildInputs = with pkgs; [pkg-config];
              };
          in {
            default = mkRustPackage pkgs.rustPlatform.buildRustPackage;
            static = mkRustPackage pkgs.pkgsStatic.rustPlatform.buildRustPackage;
          };

          pre-commit = {
            check.enable = true;
            settings = {
              hooks = {
                alejandra.enable = true;
                rustfmt.enable = true;
                deadnix.enable = true;
                statix.enable = true;
              };
            };
          };

          treefmt = {
            projectRootFile = "flake.nix";
            programs = {
              alejandra.enable = true;
              deadnix.enable = true;
              statix.enable = true;
              mdformat.enable = true;
            };
            settings = {
              on-unmatched = "info";
            };
          };
        };
    };
}