kernelspace 0.1.0

Standard library for kernelspace
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

ENTRY(_start)

SECTIONS {
    . = 0x100000;

    .text : ALIGN(0x1000) {
        PROVIDE(_text_start = .);
        *(.text._start)
        *(.text*)
        PROVIDE(_text_end = .);
    } :text

    .rodata : ALIGN(0x1000) {
        PROVIDE(_rodata_start = .);
        *(.rodata*)
        *(.rodata.*)
        PROVIDE(_rodata_end = .);
    } :rodata

    .eh_frame : {
        PROVIDE(_eh_frame_start = .);
        *(.eh_frame)
        *(.eh_frame.*)
        PROVIDE(_eh_frame_end = .);
    } :rodata

    .got : {
        PROVIDE(_got_start = .);
        *(.got)
        *(.got.*)
        PROVIDE(_got_end = .);
    } :data

    .data : ALIGN(0x1000) {
        PROVIDE(_data_start = .);
        *(.data*)
        *(.data.*)
        *(.sdata*)
        PROVIDE(_data_end = .);
    } :data

    /* Make sure the .got is initialized to zero when loaded into memory */
    .dynamic : {
        PROVIDE(_dynamic_start = .);
        *(.dynamic)
        PROVIDE(_dynamic_end = .);
    } :data

    .bss : ALIGN(0x1000) {
        PROVIDE(_bss_start = .); /* . stands for "here" */
        *(.bss*)
        *(.bss.*)
        *(.sbss*)
        *(COMMON)
        . = ALIGN(16);
        PROVIDE(_bss_end = .);
    } :data

    /* Discard debug sections */
    /DISCARD/ : {
        *(.comment)
        *(.debug_*)
        *(.note.*)
        *(.gcc_except_table)
    }
}

/* We need to initialize BSS to zero */
PROVIDE(__bss_size = _bss_end - _bss_start);

PHDRS
{
    text    PT_LOAD FLAGS(5);      /* 5 = rx */
    rodata  PT_LOAD FLAGS(4);      /* 4 = r */
    data    PT_LOAD FLAGS(6);      /* 6 = rw */
}