kcl-lib 0.2.144

KittyCAD Language implementation and tools
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168

@no_std
@settings(defaultLengthUnit = mm, kclVersion = 1.0, experimentalFeatures = allow)

import assert from "std"
import * from "std::array"
import pow, sqrt from "std::math"

/// Adds every element of u to its corresponding element in v.
/// Both vectors must have the same length. Returns a new vector of the same length.
/// In other words, component-wise addition.
/// ```kcl,sketchSyntaxAgnostic
/// u = [1, 2, 3]
/// v = [10, 10, 10]
/// v2 = vector::add(u, v)
/// assert(v2[0], isEqualTo = 11)
/// assert(v2[1], isEqualTo = 12)
/// assert(v2[2], isEqualTo = 13)
/// ```
@(feature_tree = false)
export fn add(@u: [number], v: [number]): [number] {
  l0 = count(u)
  l1 = count(v)
  assert(l0, isEqualTo = l1, error = "The two input vectors must be the same length")
  arrayRange = [0..<l0]
  return reduce(arrayRange, initial = [], f = fn(@i, accum) {
    return push(accum, item = u[i] + v[i])
  })
}

/// Subtracts from every element of u its corresponding element in v.
/// Both vectors must have the same length. Returns a new vector of the same length.
/// In other words, component-wise subtraction.
/// ```kcl,sketchSyntaxAgnostic
/// u = [10, 10, 10]
/// v = [1, 2, 3]
/// v2 = vector::sub(u, v)
/// assert(v2[0], isEqualTo = 9)
/// assert(v2[1], isEqualTo = 8)
/// assert(v2[2], isEqualTo = 7)
/// ```
@(feature_tree = false)
export fn sub(@u: [number], v: [number]): [number] {
  l0 = count(u)
  l1 = count(v)
  assert(l0, isEqualTo = l1, error = "The two input vectors must be the same length")
  arrayRange = [0..<l0]
  return reduce(arrayRange, initial = [], f = fn(@i, accum) {
    return push(accum, item = u[i] - v[i])
  })
}


/// Multiplies every element of u by its corresponding element in v.
/// Both vectors must have the same length. Returns a new vector of the same length.
/// In other words, component-wise multiplication.
/// ```kcl,sketchSyntaxAgnostic
/// u = [10, 10, 10]
/// v = [1, 2, 3]
/// v2 = vector::mul(u, v)
/// assert(v2[0], isEqualTo = 10)
/// assert(v2[1], isEqualTo = 20)
/// assert(v2[2], isEqualTo = 30)
/// ```
@(feature_tree = false)
export fn mul(@u: [number], v: [number]): [number] {
  l0 = count(u)
  l1 = count(v)
  assert(l0, isEqualTo = l1, error = "The two input vectors must be the same length")
  arrayRange = [0..<l0]
  return reduce(arrayRange, initial = [], f = fn(@i, accum) {
    return push(accum, item = u[i] * v[i])
  })
}


/// Divides every element of u by its corresponding element in v.
/// Both vectors must have the same length. Returns a new vector of the same length.
/// In other words, component-wise division.
/// ```kcl,sketchSyntaxAgnostic
/// u = [10, 10, 10]
/// v = [1, 2, 3]
/// v2 = vector::div(u, v)
/// assert(v2[0], isEqualTo = 10)
/// assert(v2[1], isEqualTo = 5)
/// assert(v2[2], isEqualTo = 3.333, tolerance = 0.01)
/// ```
@(feature_tree = false)
export fn div(@u: [number], v: [number]): [number] {
  l0 = count(u)
  l1 = count(v)
  assert(l0, isEqualTo = l1, error = "The two input vectors must be the same length")
  arrayRange = [0..<l0]
  return reduce(arrayRange, initial = [], f = fn(@i, accum) {
    return push(accum, item = u[i] / v[i])
  })
}

/// Find the cross product of two 3D points or vectors.
/// ```kcl,sketchSyntaxAgnostic
/// vx = [1, 0, 0]
/// vy = [0, 1, 0]
/// vz = vector::cross(vx, v = vy)
/// assert(vz[0], isEqualTo = 0)
/// assert(vz[1], isEqualTo = 0)
/// assert(vz[2], isEqualTo = 1)
/// ```
@(feature_tree = false)
export fn cross(@u: Point3d, v: Point3d) {
  return [
    u[1] * v[2] - (u[2] * v[1]),
    u[2] * v[0] - (u[0] * v[2]),
    u[0] * v[1] - (u[1] * v[0])
  ]
}

/// Find the dot product of two points or vectors of any dimension.
/// ```kcl,sketchSyntaxAgnostic
/// u = [1, 2, 3]
/// v = [4, -5, 6]
/// dotprod = vector::dot(u, v)
/// assert(dotprod, isEqualTo = 12)
/// ```
@(feature_tree = false)
export fn dot(@u: [number], v: [number]): number {
  l0 = count(u)
  l1 = count(v)
  assert(l0, isEqualTo = l1, error = "The two input vectors must be the same length")
  return reduce(
    [0..<l0],
    initial = 0,
    f = fn(@i, accum) {
      item = u[i] * v[i]
      return accum + item
    },
  )
}

/// Find the Euclidean distance of a vector.
/// ```kcl,sketchSyntaxAgnostic
/// v = [3, 4]
/// m = vector::magnitude(v)
/// assert(m, isEqualTo = 5)
/// ```
@(feature_tree = false)
export fn magnitude(@v: [number]): number {
  return reduce(
    [0..<count(v)],
    initial = 0,
    f = fn(@i, accum) {
      item = pow(v[i], exp = 2) 
      return accum + item
    },
  )
  |> sqrt()
}

/// Normalize a vector (with any number of dimensions)
/// ```kcl,sketchSyntaxAgnostic
/// v = [3, 4]
/// normed = vector::normalize(v)
/// assert(normed[0], isEqualTo = 0.6)
/// assert(normed[1], isEqualTo = 0.8)
/// ```
@(feature_tree = false)
export fn normalize(@v: [number]): [number] {
  mag = magnitude(v)
  return map(v, f = fn(@i) { return i/mag })
}