jslt 0.0.6

Everyones favorite xslt but for json
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98

Jslt = _{ SOI ~ Expr ~ EOI }

Value = _{ FunctionCall | Accessor | Scope | Variable | Array | Object | Number | String | Boolean | Null }

Expr = _{ OperatorExpr | ValueExpr }
ValueExpr = _{ VariableDef | FunctionDef | IfStatement | Value }
OperatorExpr = { ValueExpr ~ (Operator ~ ValueExpr)+ }

Operator = _{ Add | Sub | Div | Mul | Gte | Gt | Lte | Lt | And | Or | Equal | NotEqual | Pipe }

Add = { "+" }
Sub = { "-" }
Mul = { "*" }
Div = { "/" }
Gt = { ">" }
Lt = { "<" }
Gte = { ">=" }
Lte = { "<=" }
Equal = { "==" }
NotEqual = { "!=" }
And = { "and" }
Or = { "or" }
Pipe = { "|" }
If = _{ "if" }
For = _{ "for" }
Def = _{ "def " }
Let = _{ "let " }

Scope = { "(" ~ Expr ~ ")" }

Accessor = ${
    (("." ~ (Ident | String)?) | KeyAccessor) ~ Accessor?
}
KeyAccessor = !{ "[" ~ (RangeAccessor | Expr) ~ "]" }
FromRangeAccessor = { Expr ~ ":" ~ Expr? }
ToRangeAccessor = { Expr? ~ ":" ~ Expr }
RangeAccessor = { FromRangeAccessor | ToRangeAccessor }

FunctionCall = ${ Ident ~ FunctionCallArgs ~ Accessor? }
FunctionCallArgs = !{ "(" ~ Expr? ~ ("," ~ Expr)* ~ ")" }

FunctionDef = { Def ~ Ident ~ "("  ~ Ident? ~ ("," ~ Ident)* ~ ")" ~ Expr ~ Expr? }

Array    = {
    "[" ~ "]"
  | "[" ~ (ArrayFor | Expr) ~ ("," ~ (ArrayFor | Expr))* ~ ","? ~ "]"
}
ArrayFor = {
    For ~ "(" ~ Expr ~ ")" ~ Expr ~ IfCondition?
}

Object    = {
    "{" ~ ObjectSpread? ~ "}"
  | "{" ~ (ObjectFor | Pair) ~ ("," ~ (ObjectSpread | ObjectFor | Pair))* ~ ","? ~ "}"
}
ObjectFor = {
    For ~ "(" ~ Expr ~ ")" ~ Pair ~ IfCondition?
}
ObjectSpread = {
    "*" ~ ":" ~ Expr
}

Pair = {
    Expr ~ ":" ~ Expr
}

IfStatement = {
    IfCondition ~ Expr ~ ("else" ~ Expr)?
}

IfCondition = {
    If ~ "(" ~ Expr ~ ")"
}

Variable = { "$" ~ Ident ~ Accessor? }
VariableDef = { Let ~ Ident ~ "=" ~ Expr ~ Expr? }

String = ${ "\"" ~ Inner ~ "\"" }
Inner  = @{ Char* }
Char   =  {
    !("\"" | "\\") ~ ANY
  | "\\" ~ ("\"" | "\\" | "/" | "b" | "f" | "n" | "r" | "t")
  | "\\" ~ ("u" ~ ASCII_HEX_DIGIT{4})
}

Ident = @{ ("_" | ASCII_ALPHANUMERIC) ~ ("_" | "-" | ASCII_ALPHANUMERIC)* }

Number = @{
    "-"? ~ ("0" | ASCII_NONZERO_DIGIT ~ ASCII_DIGIT*) ~ ("." ~ ASCII_DIGIT*)? ~ (^"e" ~ ("+" | "-")? ~ ASCII_DIGIT+)?
}

Boolean = { "true" | "false" }

Null = { "null" }

COMMENT = _{ "//" ~ (!NEWLINE ~ ANY)* }

WHITESPACE = _{ " " | "\t" | NEWLINE }