jrsonnet-gcmodule 0.5.0

Cyclic garbage collection inspired by CPython's gc implementation.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107

{
  description = "Gcmodule";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/release-25.11";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };
    crane.url = "github:ipetkov/crane";
    shelly.url = "github:CertainLach/shelly";
  };
  outputs =
    inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [ inputs.shelly.flakeModule ];
      systems = inputs.nixpkgs.lib.systems.flakeExposed;
      perSystem =
        {
          config,
          system,
          ...
        }:
        let
          pkgs = import inputs.nixpkgs {
            inherit system;
            overlays = [ inputs.fenix.overlays.default ];
          };
          toolchain = pkgs.fenix.combine [
            (pkgs.fenix.stable.withComponents [
              "cargo"
              "clippy"
              "rustc"
              "rust-src"
            ])
            pkgs.fenix.complete.rustfmt
          ];
          miriToolchain = pkgs.fenix.complete.withComponents [
            "cargo"
            "rustc"
            "rust-src"
            "miri"
          ];
          craneLib = (inputs.crane.mkLib pkgs).overrideToolchain toolchain;
          miriCraneLib = (inputs.crane.mkLib pkgs).overrideToolchain miriToolchain;
          src = craneLib.cleanCargoSource ./.;
        in
        {
          # Won't pass with the updated tree borrows implementation
          checks.miri = miriCraneLib.mkCargoDerivation ({
            inherit src;
            name = "miri-tests";
            buildPhaseCargoCommand = ''
              cargo miri test --features=nightly
            '';
            env.MIRIFLAGS = "-Zmiri-tree-borrows";

            cargoArtifacts = null;
            doInstallCargoArtifacts = false;

            MIRI_SYSROOT = miriCraneLib.mkCargoDerivation {
              pname = "miri-sysroot";
              version = "0.0.0";
              dontUnpack = true;
              buildPhaseCargoCommand = ''
                MIRI_SYSROOT=$out cargo miri setup
              '';
              dontFixup = true;
              cargoLock = pkgs.runCommand "sysroot-cargoLock" { nativeBuildInputs = [ miriToolchain ]; } ''
                cp `rustc --print sysroot`/lib/rustlib/src/rust/library/Cargo.lock $out
              '';
              cargoArtifacts = null;
            };
          });
          shelly.shells = {
            verification = {
              factory = miriCraneLib.devShell;
              packages =
                with pkgs;
                [
                  cargo-edit
                  lld
                  hyperfine
                  graphviz
                  rust-analyzer-nightly
                  cargo-fuzz
                  cargo-edit
                ]
                ++ lib.optionals (!stdenv.isDarwin) [
                  valgrind
                ];
            };
            default = {
              factory = craneLib.devShell;
              packages = with pkgs; [
                cargo-edit
                rust-analyzer-nightly
                cargo-edit
              ];
            };
          };
        };
    };
}