jojo 0.1.1

JOJO's Bizarre Programming Adventure.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159

(note
  Event == String
  Process == (-> Event -- Process))

(note
  thus a process is a closure in jojo
  while the special process STOP simply returns a 'bleep)

(+jojo STOP {drop 'bleep})

(+jojo prefix (-> :event :process -- Process)
  {(-> :x -- Process)
   (if [:x :event eq?]
       :process
       'bleep)})

(+jojo dict-choice (-> :dict -- Process)
  {(-> :event -- Process)
   (if [:dict :event dict-find]
     []
     'bleep)})

(+jojo menu (-> :event-list :process -- Event List)
  (cond [:event-list null?] null

        [:event-list .car :process apply 'bleep eq?]
        [:event-list .cdr :process menu]

        else [:event-list .car
              :event-list .cdr :process menu
              cons]))

(import sys)

(+jojo readline sys .stdin -1 swap .readline)

(+jojo read-event
  readline code-scan :string-vect!
  (if [:string-vect vect-length 0 eq?]
    read-event
    [:string-vect 0 vect-ref]))

(+jojo interact (-> :event-list :process --)
  :event-list :process menu p nl
  read-event :event!
  (when [:event 'end eq? not]
    :event :process apply :next!
    (cond [:next 'bleep eq?]
          ['bleep p nl :event-list :process interact]
          else [:event-list :next interact])))

(+jojo - (-> :body -- Sexp)
  (cond [:body null?]
        ["- (-) syntax error" p nl
         "  body of (-) can not be null" p nl
         error]
        [:body.cdr null?]
        `{(@ :body.car) apply}
        else
        `[(quote (@ :body.car))
          (- (@ :body.cdr list-spread))
          prefix]))

(note
  (+jojo VMS
    (- coin choc VMS))
  ==>
  (+jojo VMS
    'coin 'choc {VMS apply}
    prefix prefix))

(+jojo | (-> :body -- Sexp)
  `(begin
     (dict (@ :body choice-recur))
     dict-choice))

(+jojo choice-recur (-> :body -- Sexp)
  (cond [:body null?] `(begin)
        else `(begin
                (quote (@ :body.car))
                {(@ :body.cdr.car) apply}
                (@ :body.cdr.cdr choice-recur))))

(note
  (+jojo CT (-> :n -- Process)
    (cond [:n 0 eq?]
          (| up [1 CT]
             around [0 CT])
          else
          (| up [:n inc CT]
             down [:n dec CT])))
  ==>
  (+jojo CT (-> :n -- Process)
    (cond [:n 0 eq?]
          [(dict
             'up {1 CT apply}
             'around {0 CT apply})
           dict-choice]
          else
          [(dict
             'up {:n inc CT apply}
             'down {:n dec CT apply})
           dict-choice])))

(+jojo CLOCK (- tick CLOCK))

(+jojo VMS-alphabet
  '(coin choc))
(+jojo VMS (- coin choc VMS))

(+jojo CH5A (- in5p out2p out1p out2p CH5A))

(+jojo CH5B (- in5p out1p out1p out1p out2p CH5B))

(+jojo CH5C-alphabet
  '(in5p out1p out2p))
(+jojo CH5C
  (- in5p (| out1p (- out1p out1p out2p CH5C)
             out2p (- out1p out2p CH5C))))

(+jojo VMCT-alphabet
  '(coin choc toffee))
(+jojo VMCT
  (- coin (| choc VMCT
             toffee VMCT)))

(+jojo VMC-alphabet
  '(in1p in2p large small))
(+jojo VMC
  (note WARNING
    do not insert three pennies in a row)
  (| in2p (| large VMC
             small (- out1p VMC))
     in1p (| small VMC
             in1p (| large VMC
                     in1p STOP))))

(+jojo COPYBIT-alphabet
  '(in.0 out.0 in.1 out.1))
(+jojo COPYBIT
  (| in.0 (- out.0 COPYBIT)
     in.1 (- out.1 COPYBIT)))

(+jojo CT-alphabet
  '(up down around))
(+jojo CT (-> :n -- Process)
  (cond [:n 0 eq?]
        (| up [1 CT]
           around [0 CT])
        else
        (| up [:n inc CT]
           down [:n dec CT])))

(note
  (begin VMS-alphabet VMS interact)
  (begin CH5C-alphabet CH5C interact)
  (begin VMCT-alphabet VMCT interact)
  (begin VMC-alphabet VMC interact)
  (begin CT-alphabet 0 CT interact))