iqan 0.3.4

Sync Nix flake pins
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79

{
  description = "íqán";

  inputs = {
    nixpkgs.url = "https://channels.nixos.org/nixos-26.05/nixexprs.tar.zst";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      fenix,
    }:
    let
      systems = [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
        "x86_64-linux"
      ];
      eachSystem = nixpkgs.lib.genAttrs systems;
    in
    {
      formatter = eachSystem (system: nixpkgs.legacyPackages.${system}.nixfmt);

      packages = eachSystem (
        system:
        let
          toolchain = fenix.packages.${system}.stable.minimalToolchain;
          pkgs = nixpkgs.legacyPackages.${system};
        in
        rec {
          default = iqan;

          iqan =
            (pkgs.makeRustPlatform {
              cargo = toolchain;
              rustc = toolchain;
            }).buildRustPackage
              {
                pname = "iqan";
                version = "0.3.4";

                src = ./.;

                cargoLock.lockFile = ./Cargo.lock;
              };
        }
      );

      devShells = eachSystem (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          default = pkgs.mkShell {
            name = "iqan";

            packages = [
              (fenix.packages.${system}.stable.withComponents [
                "cargo"
                "rustc"
                "rust-analyzer"
                "clippy"
                "rustfmt"
                "rust-src"
              ])
              pkgs.cargo-nextest
            ];
          };
        }
      );
    };
}