iota-sdk 0.3.0

The IOTA SDK provides developers with a seamless experience to develop on IOTA by providing account abstractions and clients to interact with node APIs.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160

plugins {
    // Apply the java-library plugin for API and implementation separation.
    id 'java-library'
    id 'c'
    id 'maven-publish'
    id 'signing'
    id 'com.google.osdetector' version '1.7.1'
}

dependencies {
    // Use JUnit Jupiter for testing.
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.9.0'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.9.0'
    // Dependencies that are used internally, and not exposed to consumers on their own compile classpath.
    implementation group: 'com.google.code.gson', name: 'gson', version: '2.8.9'
    implementation group: 'org.apache.commons', name: 'commons-lang3', version: '3.12.0'
    implementation group: 'commons-codec', name: 'commons-codec', version: '1.15'
}

repositories {
    mavenCentral()
}

java {
    sourceCompatibility = "1.8"
    targetCompatibility = "1.8"

    withJavadocJar()
    withSourcesJar()
}

javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

task buildRustRelease(type:Exec){
    workingDir 'native'

    if (!project.hasProperty('buildTarget')) {
        commandLine 'cargo', 'build', '--release'
    } else {
        commandLine 'cargo', 'build', '--target=' + buildTarget, '--release'
    }
}

archivesBaseName = 'iota-client'

jar {
    dependsOn 'buildRustRelease'

    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

    if (!project.hasProperty('buildTarget')) {
        from('../../../../../../target/release') {
            include '*.so', '*.dylib', '*.dll'
        }
    } else {
        from('../../../../../../target/' + findProperty('buildTarget') + '/release') {
            include '*.so', '*.dylib', '*.dll'
        }
    }

    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }

    archiveClassifier = getJarClassifier()
}

task jarWithoutNativeLibs(type: Jar) {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }

    exclude '*.so', '*.dylib', '*.dll'

    with jar
}

test {
    doFirst {
        classpath += jar.outputs.files
    }
    useJUnitPlatform()
}

version = project.getRootProject().properties.version

publishing {
    publications {
        allJars (MavenPublication) {
            groupId = 'org.iota'
            artifactId = 'iota-client'

            artifact jarWithoutNativeLibs

            from components.java

            pom {
                name = 'iota-client'
                description = 'Java binding to the iota.rs library.'
                url = 'https://github.com/iotaledger/iota.rs'
                inceptionYear = '2022'

                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id = 'samuel-rufi'
                        name = 'Samuel Rufinatscha'
                        email = 'samuel.rufinatscha@iota.org'
                    }
                }

                scm {
                    connection = 'scm:git:git:github.com/iotaledger/iota.rs.git'
                    developerConnection = 'scm:git:ssh://github.com/iotaledger/iota.rs.git'
                    url = 'https://github.com/iotaledger/iota.rs'
                }
            }
        }
    }
}

signing {
    // The ASCII armored signing key contains important new line characters that are lost when loading the content for example like: `def signingKey = findProperty("signingKey"))`
    // To solve this, encode the ASCII armored signing key in base64 and store it in the `ORG_GRADLE_PROJECT_base64EncodedAsciiArmoredSigningKey` environment variable.
    // The following line will decode it correctly:
    def signingKey = base64Decode(findProperty("base64EncodedAsciiArmoredSigningKey"))
    def signingPassword = findProperty("signingPassword")
    useInMemoryPgpKeys(signingKey, signingPassword)

    sign publishing.publications.allJars
}

def base64Decode(encodedString){
    if(encodedString != null) {
        byte[] decoded = encodedString.decodeBase64()
        String decode = new String(decoded)
        return decode
    }
    return null;
}

def getJarClassifier(){
    def buildTarget = findProperty("buildTarget")
    if(buildTarget != null)
        return buildTarget
    else
        return osdetector.classifier
}