hyprshell 4.9.5

A modern GTK4-based window switcher and application launcher for Hyprland
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93

{
  craneLib,
  pkgs,
}:
rec {
  meta = import ./meta.nix { inherit pkgs; };
  pname = "hyprshell";
  version = (pkgs.lib.trivial.importTOML ../Cargo.toml).workspace.package.version;
  # no more filtering, excluded to many files
  src = ../.;
  stdenv = p: p.stdenv;
  # use in preFixup
  addWrapWithGccArgs = hyprland: ''
    gappsWrapperArgs+=(
       --prefix PATH : '${pkgs.lib.makeBinPath [ pkgs.gcc ]}'
       --prefix CPATH : '${
         pkgs.lib.makeIncludePath (
           hyprland.buildInputs
           ++ [
             hyprland
             pkgs.pixman
           ]
         )
       }:${pkgs.libdrm.dev}/include/libdrm'
     )
  '';
  commonArgs = {
    inherit
      src
      stdenv
      pname
      version
      meta
      ;
    strictDeps = true;
    doCheck = false;
    cargoBuildCommand = "cargo build --release --locked";
    cargoTestCommand = "";
    cargoCheckCommand = "";
    cargoCheckExtraArgs = "";
    cargoExtraArgs = "";

    nativeBuildInputs = [
      pkgs.pkg-config
      pkgs.wrapGAppsHook4
    ];

    buildInputs = [
      pkgs.libadwaita
      pkgs.gtk4-layer-shell
    ];
  };

  cargoReleaseArtifacts = craneLib.buildDepsOnly (
    commonArgs
    // {
      mkDummySrc = craneLib.mkDummySrc {
        inherit stdenv;
        src = ../.;
      };
      pname = "hyprshell";
    }
  );
  cargoFullArtifacts = craneLib.buildDepsOnly (
    commonArgs
    // {
      src = craneLib.cleanCargoSource ../.;
      pname = "hyprshell-full";
      doCheck = true;
      cargoBuildCommand = "cargo build --profile dev --locked --all-targets --all-features";
      cargoCheckCommand = "cargo check --profile dev --locked --all-targets --all-features";
      cargoTestCommand = "cargo test --profile dev --locked --all-targets --all-features";
    }
  );
  commonArgsFullCached = (
    commonArgs
    // {
      cargoArtifacts = cargoFullArtifacts;
    }
  );

  postInstall = ''
    # Desktop entry
    install -Dm644 packaging/hyprshell-settings.desktop $out/share/applications/hyprshell-settings.desktop

    # Icon
    install -Dm644 packaging/hyprshell-settings.png $out/share/pixmaps/hyprshell-settings.png

    # Extract runtime data
    mkdir -p $out/share/hyprshell
    tar -xf packaging/usr-share.tar -C $out/share/hyprshell
  '';
}