httpql 0.8.0

Parser for the HTTPQL language
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103

HTTPQL = { SOI ~ Query? ~ EOI }

// Tokens
// Delimiters
LeftParen  = _{ "(" }
RightParen = _{ ")" }
Dot        = _{ "." }
Colon      = _{ ":" }

// Logical operators
And = { "AND" | "and" }
Or  = { "OR" | "or" }

// Namespaces
RowNamespace      = _{ "row" }
RequestNamespace  = _{ "req" }
ResponseNamespace = _{ "resp" }
PresetNamespace   = _{ "preset" }
SourceNamespace   = _{ "source" }

// Row field names
RowIntFieldName = { "id" }

// Request field names
RequestStringFieldName = { "ext" | "host" | "method" | "path" | "query" | "raw" }
RequestIntFieldName    = { "len" | "port" }
RequestDateFieldName   = { "created_at" }
RequestBoolFieldName   = { "tls" }

// Response field names
ResponseStringFieldName = { "raw" }
ResponseIntFieldName    = { "code" | "len" | "roundtrip" }

// Operators for string and integer types
StringOperator = { "cont" | "ncont" | "eq" | "ne" | "like" | "nlike" }
RegexOperator  = { "regex" | "nregex" }
IntOperator    = { "eq" | "gte" | "gt" | "lte" | "lt" | "ne" }
DateOperator   = { "lt" | "gt" }
BoolOperator   = { "eq" | "ne" }

// Value types
SymbolValue   = @{ ('a'..'z' | '0'..'9' | "-" | "_")+ }
IntValue      = @{ ASCII_DIGIT+ }
StringValue   = @{ "\"" ~ StringContent ~ "\"" }
StringContent =  { StringChar* }
StringChar    =  {
    !("\"" | "\\") ~ ANY
  | "\\" ~ ("\"" | "\\" | "/" | "b" | "f" | "n" | "r" | "t")
  | "\\" ~ ("u" ~ ASCII_HEX_DIGIT{4})
}
RegexValue    = ${ "/" ~ RegexContent ~ "/" }
RegexContent  = @{ RegexChar* }
RegexChar     =  {
    "\\" ~ ANY
  | !"/" ~ ANY
}
BoolValue     =  { "true" | "false" }

// Define non-token rules for constructing expressions
WHITESPACE     = _{ " " | "\t" | LineTerminator }
COMMENT        = _{ LineComment | BlockComment }
BlockComment   = _{ "/*" ~ (!"*/" ~ ANY)* ~ "*/" }
LineComment    = _{ "//" ~ (!LineTerminator ~ ANY)* }
LineTerminator = @{ "\r\n" | "\r" | "\n" }

// Expression
IntExpression         = ${ IntOperator ~ Colon ~ IntValue }
StringExpression      = ${ StringOperator ~ Colon ~ StringValue | RegexOperator ~ Colon ~ (RegexValue | StringValue) }
DateExpression        = ${ DateOperator ~ Colon ~ StringValue }
BoolExpression        = ${ BoolOperator ~ Colon ~ BoolValue }
PresetNameExpression  =  { StringValue }
PresetAliasExpression =  { SymbolValue }
SourceNameExpression  =  { StringValue }

// Clause
StringClause = { StringValue }

RowClause = ${ RowNamespace ~ Dot ~ RowIntFieldName ~ Dot ~ IntExpression }

RequestClause = ${
    RequestNamespace ~ Dot ~ RequestIntFieldName ~ Dot ~ IntExpression
  | RequestNamespace ~ Dot ~ RequestStringFieldName ~ Dot ~ StringExpression
  | RequestNamespace ~ Dot ~ RequestDateFieldName ~ Dot ~ DateExpression
  | RequestNamespace ~ Dot ~ RequestBoolFieldName ~ Dot ~ BoolExpression
}

ResponseClause = ${
    ResponseNamespace ~ Dot ~ ResponseIntFieldName ~ Dot ~ IntExpression
  | ResponseNamespace ~ Dot ~ ResponseStringFieldName ~ Dot ~ StringExpression
}

PresetClause = ${
    PresetNamespace ~ Colon ~ (PresetNameExpression | PresetAliasExpression)
}

SourceClause = ${
    SourceNamespace ~ Colon ~ SourceNameExpression
}

// Query
Clause          = _{ StringClause | RowClause | RequestClause | ResponseClause | PresetClause | SourceClause | LeftParen ~ Query ~ RightParen }
LogicalOperator = _{ And | Or }
Query           =  { (Clause ~ (LogicalOperator ~ Clause)*)? }