hinoirisetr 1.6.2

A daemon to dim the screen at night
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91

{
  description = "DevShell for hinoirisetr";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs =
    {
      nixpkgs,
      rust-overlay,
      ...
    }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      # Helper function to generate an attrset '{ x86_64-linux = f "x86_64-linux"; ... }'.
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;

      # Nixpkgs instantiated for supported system types.
      overlays = [ (import rust-overlay) ];
      nixpkgsFor = forAllSystems (system: import nixpkgs { inherit system overlays; });
    in
    {

      packages = forAllSystems (
        system:
        let
          pkgs = nixpkgsFor.${system};
        in
        {
          default = pkgs.rustPlatform.buildRustPackage {
            pname = "hinoirisetr";
            version = "1.6.2";

            src = ./.;

            cargoLock = {
              lockFile = ./Cargo.lock;
            };

            postFixup = ''
              patchelf $out/bin/hinoirisetr --add-rpath ${pkgs.libnotify}/lib
            '';

            postBuild = ''
              pandoc manpages/hinoirisetr.1.md -s -t man -o $out/share/man/man1/hinoirisetr.1
            '';

            preBuild = ''
              mkdir -p $out/share/man/man1
            '';

            nativeBuildInputs = [ pkgs.pandoc ];
            buildInputs = [ pkgs.libnotify ];
          };

        }
      );

      devShells = forAllSystems (
        system:
        let
          pkgs = nixpkgsFor.${system};
          rust = pkgs.rust-bin.stable.latest.default.override {
            extensions = [
              "rust-analyzer"
              "rust-src"
            ];
          };
        in
        {
          default = pkgs.mkShell rec {
            buildInputs = [
              rust
              pkgs.libnotify
              pkgs.pandoc
            ];

            shellHook = ''
              export LD_LIBRARY_PATH="${pkgs.lib.makeLibraryPath buildInputs}";
            '';
          };
        }
      );
    };
}