himalaya 2.2.1

CLI to manage emails
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84

{
  nixpkgs ? <nixpkgs>,
  pimalaya ? import (fetchTarball "https://github.com/pimalaya/nix/archive/master.tar.gz"),
  ...
}@args:

let
  himalaya = import ./default.nix (
    removeAttrs args [
      "crossPkgs"
      "isStatic"
      "target"
    ]
  );

in
pimalaya.mkDefault (
  {
    src = ./.;
    version = "2.2.1";
    mkPackage = (
      {
        lib,
        pkgs,
        rustPlatform,
        defaultFeatures,
        features,
        buildPackages,
      }:

      let
        inherit (pkgs) sqlite stdenv windows;

        # NOTE: nixpkgs' mingw sqlite fails its pthread probe and compiles
        # single-threaded, defining no sqlite3_mutex_* rusqlite links against
        sqlite' =
          if stdenv.hostPlatform.isWindows then
            sqlite.overrideAttrs (old: {
              buildInputs = (old.buildInputs or [ ]) ++ [ windows.pthreads ];
            })
          else
            sqlite;

        buildFeatures = lib.splitString "," features;

        systemSqlite =
          (defaultFeatures || builtins.elem "pimdir" buildFeatures)
          && !builtins.elem "vendored" buildFeatures;

      in
      (pkgs.callPackage "${nixpkgs}/pkgs/by-name/hi/himalaya/package.nix" {
        inherit lib rustPlatform buildFeatures;
        buildPackages = buildPackages // {
          inherit himalaya;
        };
        installShellCompletions = false;
        installManPages = false;
        buildNoDefaultFeatures = !defaultFeatures;
      })
      # HACK: needed until the v2.1.0 derivation lands on nixpkgs's master
      .overrideAttrs
        (drv: {
          buildInputs = (drv.buildInputs or [ ]) ++ lib.optional systemSqlite sqlite';

          postInstall =
            let
              inherit (pkgs) stdenv;
              exe =
                if stdenv.buildPlatform.canExecute stdenv.hostPlatform then
                  "$out/bin/himalaya"
                else
                  lib.getExe himalaya;
            in
            ''
              mkdir -p $out/share/{completions,man,schemas}
              ${exe} completion -d "$out"/share/completions bash elvish fish powershell zsh
              ${exe} manual -d "$out"/share/man
              ${exe} json-schema -d "$out"/share/schemas
            '';
        })
    );
  }
  // removeAttrs args [ "pimalaya" ]
)