hen 0.8.0

Run API collections from the command line.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

section_delim = _{ "---" }
whitespace    = _{ " " | "\t" }

collection_name        = { "name" ~ whitespace* ~ "=" ~ whitespace* ~ value ~ NEWLINE }
collection_description = { "description" ~ whitespace* ~ "=" ~ whitespace* ~ value }

variable = { "$" ~ whitespace* ~ key ~ whitespace* ~ "=" ~ whitespace* ~ value }

key   = { (!"=" ~ ANY)+ }
value = { (!"\n" ~ ANY)+ }

preamble = _{ NEWLINE* ~ ((collection_name | collection_description | variable | header | query | callback) ~ NEWLINE*)+ }

http_method = { "GET" | "PUT" | "POST" | "PATCH" | "DELETE" | "OPTIONS" }

header = { "*" ~ whitespace* ~ key ~ whitespace* ~ "=" ~ whitespace* ~ value }

query = { "?" ~ whitespace* ~ key ~ whitespace* ~ "=" ~ whitespace* ~ value }

file = { "@" ~ whitespace* ~ value }
text = { value }
form = { "~" ~ whitespace* ~ key ~ whitespace* ~ "=" ~ whitespace* ~ (file | text) }

callback = { "!" ~ whitespace* ~ value }

body_content_type =  { value }
body              =  { (!"~~~" ~ ANY)+ }
body_block        = _{ "~~~" ~ whitespace* ~ body_content_type* ~ NEWLINE ~ body* ~ "~~~" }

url = { (!"\n" ~ ANY)+ }

description = { !http_method ~ value ~ NEWLINE }

request = {
    description* ~ NEWLINE* ~ http_method ~ whitespace+ ~ url ~ (header | query | body_block | form | callback | NEWLINE)*
}

requests = {
    request ~ (section_delim ~ NEWLINE+ ~ request)*
}

request_collection = { (preamble ~ section_delim ~ NEWLINE*)* ~ requests }