harborc 0.1.1

A language that ports: targeting your thermostat, UFO, and kitchen sink.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134

use crate::mir::*;

grammar;


List<T>: Vec<T> = {
    <items: (T ",")*> <last: T> ","? => {
        let mut items = items.into_iter().map(|(item, _)| item).collect::<Vec<_>>();
        items.push(last);
        items
    }
}

pub MIR: Op = Expr => <>;
Expr: Op = {
    "let" <mut defs: List<(Identifier "=" Expr)>> "in" <ret:Expr+> "end" => {
        let (name, _, val) = defs.pop().unwrap();
        let mut result = Op::Let(name, vec![val], ret);

        while let Some((name, _, expr)) = defs.pop() {
            result = Op::Let(name, vec![expr], vec![result]);
        }

        result
    },

    "do" <Expr+> "end" => Op::Do(<>),

    "while" <cond: Expr> "do" <body: Expr+> "end" => {
        Op::While(vec![cond], body)
    },

    "if" <cond: Expr> "do" <body: Expr+> "end" => {
        Op::If(vec![cond], body)
    },

    "frame" <args:Size> "->" <ret:Size> "do" <code:Expr+> "end" => {
        Op::Frame(args, ret, code)
    },

    "fn" "(" <args: List<(Identifier ":" Size)>> ")" "->" <ret_size:Size> "do" <code:Expr+> "end" => {
        function(args.into_iter().map(|(name, _, size)| (name, size)).collect(), ret_size, code)
    },

    AtomicExpr => <>,
}

AtomicExpr: Op = {
    "(" <Expr+> ")" => Op::Do(<>),

    "alloc" => Op::Do(vec![
        Op::Alloc,
    ]),
    "free" => Op::Free,

    "get" <Size> => Op::Do(vec![
        Op::Stalloc(<>),
    ]),
    "dup" => Op::Duplicate,
    "dump" <Size> => Op::Stfree(<>),

    <Num> => Op::PushLiteral(Literal(<>)),
    "=" <Size> => Op::Store(<>),
    "=" => Op::Store(1),
    "@" => Op::Load(1),

    "+" => Op::Add,
    "-" => Op::Sub,
    "*" => Op::Mul,
    "/" => Op::Div,

    "==" => Op::Eq,
    "!=" => Op::Neq,

    "!" => Op::Not,
    "&" => Op::And,
    "|" => Op::Or,

    "$FP" => Op::LoadFrom(FP, 1),
    "$R0" => Op::LoadFrom(R0, 1),
    "$R1" => Op::LoadFrom(R1, 1),
    "$R2" => Op::LoadFrom(R2, 1),
    "$R3" => Op::LoadFrom(R3, 1),
    "$R4" => Op::LoadFrom(R4, 1),
    "$R5" => Op::LoadFrom(R5, 1),

    "&FP" => Op::PushAddress(FP.get_address().unwrap()),
    "&R0" => Op::PushAddress(R0.get_address().unwrap()),
    "&R1" => Op::PushAddress(R1.get_address().unwrap()),
    "&R2" => Op::PushAddress(R2.get_address().unwrap()),
    "&R3" => Op::PushAddress(R3.get_address().unwrap()),
    "&R4" => Op::PushAddress(R4.get_address().unwrap()),
    "&R5" => Op::PushAddress(R5.get_address().unwrap()),

    Identifier => Op::Macro(<>),
}

Size: u32 = {
    "%" <AtomicSize> => <>,
}

AtomicSize: u32 = {
    "void" => 0,
    "int" => 1,
    "char" => 1,
    "bool" => 1,
    "(" <first:(Size ",")+> <last:Size?> ")" => {
        let mut result = 0;

        for (size, _) in first {
            result += size;
        }
        if let Some(size) = last {
            result += size;
        }

        result
    }
}

Str: String = <s:r#""(\\.|[^"])*""#> => String::from(&s[1..s.len()-1]).replace("\\\"", "\"").replace("\\n", "\n").replace("\\r", "\r").replace("\\t", "\t").replace("\\0", "\0");
Char: char = <s:r#"'(\\.|[^'])'"#> => s.replace("\\'", "'").replace("\\n", "\n").replace("\\r", "\r").replace("\\t", "\t").replace("\\0", "\0").chars().nth(1).unwrap() as char;
Bool: bool = {
    "true" => true,
    "false" => false,
}

Num: u32 = {
    r"[1-9][0-9]*|[0]" => {
        <>.parse::<u32>().unwrap()
    },
}

Identifier: String = r"[a-zA-Z_][a-zA-Z0-9_]*" => <>.to_string();