hallouminate 0.1.2

A markdown corpus indexer for LLMs to build and query their own per-repo wikis.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# hallouminate dev commands — run `just` to list recipes.
#
# rustup honors rust-toolchain.toml (the crate's MSRV). protoc must be
# installed locally for the lancedb build script:
#   macOS:  brew install protobuf
#   Debian: sudo apt-get install -y protobuf-compiler

default:
    @just --list

# CI gate — checks only, no writes (mirrors .github/workflows/ci.yml).
ci: _fmt-check _clippy _build _test

# For agents/LLMs — auto-fix formatting + machine-applicable lints, then verify.
llm: _fix _clippy _build _test

# Move v<version> to HEAD and push, retriggering release.yml + publish-crates.yml.
# Use to re-ship the SAME version after landing a release fix on main.
re-tag version:
    @git diff --quiet HEAD || { echo "working tree dirty — commit first"; exit 1; }
    -git push origin :refs/tags/v{{version}}
    -git tag -d v{{version}}
    git tag v{{version}}
    git push origin v{{version}}

_fmt-check:
    cargo fmt --all --check

_fix:
    cargo clippy --fix --all-targets --all-features --allow-dirty --allow-staged
    cargo fmt --all

_clippy:
    cargo clippy --locked --all-targets --all-features -- -D warnings

_build:
    cargo build --locked --all-targets

_test:
    cargo test --locked