hack_asm 1.0.2

A Nand2Tetris Hack Assembly Language Assembler written in Rust
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

// globally allowed whitespace
WHITESPACE = _{ " " | "\t" }

// symbol
symbol_inner = @{ ASCII_ALPHANUMERIC | "." | "_" | "$" | "%" | "#"}
symbol_begin = @{ ASCII_ALPHA | "." | "_" | "$" | "%" | "#"}

// @-instructions
symbol = @{ symbol_begin ~ symbol_inner* }
literal = @{ ASCII_DIGIT+ }
at_instruction = { "@" ~ (literal | symbol)}

// comment
comment = _{ "//" ~ (!NEWLINE ~ ANY)* }

// label
label = { "(" ~ symbol ~ ")" }

// constants
one = { "1" }
zero = { "0" }
neg_one = { "-1" }
constant = { one | zero | neg_one }

// operators / destination
register = { (^"A" | ^"M" | ^"D") }

// operation helpers
inc = { "+" ~ "1" }
dec = { "-" ~ "1" }
not = { "!" }
neg = { "-" }
unary_pre = _{ ( not| neg ) ~ register }
unary_post = _{ register ~ (inc | dec )}
binary_op = { "+" | "|" | "-" | "&" }

// operations
unary = { unary_pre | unary_post }
binary = { register ~ binary_op ~ register}

// c-instruction
destination = { register{0,3} }
computation = { constant | unary | binary | register }
jump = { ^"JMP" | ^"JGT" | ^"JEQ"| ^"JLT" | ^"JGE" | ^"JLE" | ^"JNE" }
c_instruction = { (destination ~ "=")? ~ computation ~ (";" ~ jump)? }

// final
instruction = _{ label | at_instruction | c_instruction }
program = { SOI ~ (instruction? ~ comment? ~ NEWLINE)* ~ EOI }