grixy 0.6.1

Zero-cost 2D grids for embedded systems and graphics
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

_default:
    cargo just --list -u

init:
    cargo tool --install

lint: lint-check

lint-check:
    cargo clippy --no-deps --all-targets --all-features -- -D warnings

lint-fix:
    cargo clippy --no-deps --all-targets --all-features --fix

format: format-fix

format-check:
    cargo fmt --all -- --check

format-fix:
    cargo fmt --all

fix:
    cargo just format-fix
    cargo just lint-fix

check:
    cargo just format-check
    cargo just lint
    cargo just doc-check

bench *ARGS:
    cargo bench --all-features {{ARGS}}

profile *ARGS:
    cargo tool flamegraph --bench {{ARGS}} -- --bench

doc:
    cargo doc --all-features --no-deps --open --lib

doc-check:
    RUSTDOCFLAGS="-D warnings" cargo doc --no-deps --all-features

semver-checks:
    # No --baseline-version pin: previously published 0.6.0-alpha.* releases all depend on a
    # loose (non-exact) ixy requirement, so cargo-semver-checks re-resolves their `ixy` dependency
    # against whatever is newest on crates.io when building the baseline - which breaks the
    # instant ixy publishes another breaking prerelease in the same 0.6.0 track (as happened
    # going from ixy 0.6.0-alpha.5 to 0.6.0-alpha.9). Letting cargo-semver-checks auto-select the
    # baseline compares against the latest actual stable release instead, which isn't affected.
    cargo tool cargo-semver-checks

msrv:
    cargo tool cargo-hack check --rust-version --workspace --all-targets --all-features --ignore-private

doc-gen:
    cargo clean --doc
    RUSTDOCFLAGS="-D warnings" cargo doc --all-features --no-deps
    echo '<meta http-equiv="refresh" content="0;url=grixy/index.html">' > target/doc/index.html
    rm target/doc/.lock

test *ARGS:
    cargo tool cargo-nextest run {{ARGS}}

test-doc *ARGS:
    cargo test {{ARGS}} --doc --all-features

test-all:
    cargo just test --all-features
    cargo just test-doc
    
coverage *ARGS:
    cargo tool cargo-llvm-cov --lib --open --all-features

coverage-gen:
    cargo tool cargo-llvm-cov --lib --lcov --all-features --output-path lcov.info