gptcommit 0.5.9

A git prepare-commit-msg hook for summarizing commits with LLMs.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

set positional-arguments
set dotenv-load := true

help:
    @just --list --unsorted

clean:
    cargo clean

build:
    cargo build
alias b := build

run *args:
    cargo run -- "$@"
alias r := run

release:
    cargo build --release

install:
    cargo install --path .

e2e: install
    sh -eux -c 'for i in ./tests/e2e/test_*.sh ; do sh -x "$i" ; done'

test *args: e2e
    cargo test
alias t := test

bench: install
    sh ./tests/bench/run_bench.sh

lint:
    cargo fmt --all -- --check
    cargo clippy --all-features --all-targets -- -D warnings --allow deprecated

fix:
    cargo fix --allow-dirty --allow-staged
    cargo clippy --all-features --all-targets --fix --allow-dirty --allow-staged -- -D warnings --allow deprecated
    cargo fmt --all
alias f := fix


# Bump version. level=major,minor,patch
version level:
    git diff-index --exit-code HEAD > /dev/null || ! echo You have untracked changes. Commit your changes before bumping the version.
    cargo set-version --bump {{level}}
    cargo update # This bumps Cargo.lock
    VERSION=$(toml get Cargo.toml package.version) && \
        git commit -am "Bump version {{level}} to $VERSION" && \
        git push origin HEAD
    git push

release-patch: lint build test
    just version patch

release-minor: lint build test
    just version minor

release-major: lint build test
    just version major