golem-cli 1.3.1

Command line interface for Golem.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144

///|
test "primitive" {
  let wit_value = @builder.Builder::new().s32(42)
  assert_eq(extract(wit_value).s32(), Some(42))
}

///|
test "single_record" {
  let wit_value = @builder.Builder::new().record(builder => {
    builder.u8(1)
    builder.enum_value(2)
    builder.flags([true, false, true])
  })
  assert_eq(extract(wit_value).field(0).unwrap().u8(), Some(1))
  assert_eq(extract(wit_value).field(1).unwrap().enum_value(), Some(2))
  assert_eq(extract(wit_value).field(2).unwrap().flags().unwrap(), [
    true, false, true,
  ])
}

///|
test "deep_record" {
  let wit_value = @builder.Builder::new().record(builder => builder.record(builder => {
    builder.s32(10)
    builder.string("hello")
  }))
  let inner = extract(wit_value).field(0).unwrap()
  assert_eq(inner.field(0).unwrap().s32(), Some(10))
  assert_eq(inner.field(1).unwrap().string(), Some("hello"))
}

///|
test "variant1" {
  let wit_value = @builder.Builder::new().variant(2, builder => builder.s32(42))
  let variant = extract(wit_value).variant().unwrap()
  assert_eq(variant.0, 2)
  assert_eq(variant.1.unwrap().s32(), Some(42))
}

///|
test "variant2" {
  let wit_value = @builder.Builder::new().variant_unit(0)
  let variant = extract(wit_value).variant().unwrap()
  assert_eq(variant.0, 0)
  assert_eq(variant.1.is_empty(), true)
}

///|
test "enum1" {
  let wit_value = @builder.Builder::new().enum_value(2)
  assert_eq(extract(wit_value).enum_value(), Some(2))
}

///|
test "flags" {
  let wit_value = @builder.Builder::new().flags([true, false, true])
  assert_eq(extract(wit_value).flags().unwrap(), [true, false, true])
}

///|
test "tuple" {
  let wit_value = @builder.Builder::new().tuple(builder => {
    builder.s32(42)
    builder.string("hello")
    builder.record(builder => builder.string("world"))
  })
  assert_eq(extract(wit_value).tuple_element(0).unwrap().s32(), Some(42))
  assert_eq(
    extract(wit_value).tuple_element(1).unwrap().string(),
    Some("hello"),
  )
  assert_eq(
    extract(wit_value).tuple_element(2).unwrap().field(0).unwrap().string(),
    Some("world"),
  )
}

///|
test "list" {
  let wit_value = @builder.Builder::new().list(builder => {
    builder.s32(1)
    builder.s32(2)
    builder.s32(3)
    builder.s32(4)
  })
  assert_eq(
    extract(wit_value).list_elements().unwrap().map(e => e.s32().unwrap()),
    [1, 2, 3, 4],
  )
}

///|
test "option1" {
  let wit_value = @builder.Builder::new().option_none()
  assert_eq(extract(wit_value).option().unwrap().is_empty(), true)
}

///|
test "option2" {
  let wit_value = @builder.Builder::new().option_some(builder => builder.s32(42))
  assert_eq(extract(wit_value).option().unwrap().unwrap().s32(), Some(42))
}

///|
test "result1" {
  let wit_value = @builder.Builder::new().result_ok(builder => builder.s32(42))
  assert_eq(
    extract(wit_value).result().unwrap().unwrap().unwrap().s32(),
    Some(42),
  )
}

///|
test "result2" {
  let wit_value = @builder.Builder::new().result_err(builder => builder.s32(42))
  assert_eq(
    extract(wit_value).result().unwrap().unwrap_err().unwrap().s32(),
    Some(42),
  )
}

///|
test "result3" {
  let wit_value = @builder.Builder::new().result_ok_unit()
  assert_eq(extract(wit_value).result().unwrap().unwrap().is_empty(), true)
}

///|
test "result4" {
  let wit_value = @builder.Builder::new().result_err_unit()
  assert_eq(extract(wit_value).result().unwrap().unwrap_err().is_empty(), true)
}

///|
test "handle" {
  let wit_value = @builder.Builder::new().handle(
    @types.Uri::{ value: "wit://test".to_string() },
    42,
  )
  assert_eq(
    extract(wit_value).handle().unwrap(),
    (@types.Uri::{ value: "wit://test".to_string() }, 42),
  )
}