gitrevset 0.2.0

A domain-specific-language to select commits in a git repo. Similar to Mercurial's revset.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104

use crate::ast::Expr;

// Binary Operator Precedence (highest to lowest):
// BinOp1: : ..
// BinOp2: & and % -
// BinOp3: | + or

grammar;

pub Expr = Expr4;

Expr4: Expr = {
    <a:Expr4> <op:BinOp3> <b:Expr3> => Expr::Fn(op.into(), vec![a, b]),
    Expr3,
};

BinOp3: &'static str = {
    "|" => "union",
    "+" => "union",
    "or" => "union",
};

Expr3: Expr = {
    <a:Expr3> <op:BinOp2> <b:Expr2> => Expr::Fn(op.into(), vec![a, b]),
    Expr2,
};

BinOp2: &'static str = {
    "&" => "intersection",
    "and" => "intersection",
    "-" => "difference",
    "%" => "only",
};

Expr2: Expr = {
    <a:Expr2> <op:BinOp1> <b:Expr15> => Expr::Fn(op.into(), vec![a, b]),
    Expr15,
};

BinOp1: &'static str = {
    ":" => "range",
    ".." => "range",
};

Expr15: Expr = {
    <pre:(<Prefix>)*> <e:Expr1> => {
        let mut e = e;
        for v in pre { e = Expr::Fn(v.into(), vec![e]); }
        e
    },
}

Expr1: Expr = {
    <e:Expr0> <post:(<Postfix>)*> => {
        let mut e = e;
        for v in post { e = Expr::Fn(v.into(), vec![e]); }
        e
    },
}

Expr0: Expr = {
    Symbol2 => Expr::Name(<>),
    <f:Symbol1> "(" <args:(Expr ",")*> <last:Expr?> ")" => {
        // Function call.
        let mut arg_list: Vec<Expr> = args.into_iter().map(|(e, _)| e).collect();
        if let Some(last_arg) = last { arg_list.push(last_arg); }
        Expr::Fn(f.into(), arg_list)
    },
    "(" <Expr> ")"
};

Prefix: &'static str = {
    "!" => "negate",
    "not " => "negate",
    "::" => "ancestors",
}

Postfix: &'static str = {
    "::" => "descendants",
    "^" => "parents",
}

Symbol2: String = {
    Symbol1 => <>,
    <escaped:r"\x22([^\x22\x5c]|\x5c.)*\x22"> => {
        // Escaped string.
        let mut result = String::with_capacity(escaped.len());
        let mut prev = '_';
        for ch in escaped[1..escaped.len()-1].chars() {
            match (prev, ch) {
                ('\\', 'n') => result.push('\n'),
                ('\\', _) => result.push(ch),
                (_, '\\') => (),
                (_, _) => result.push(ch),
            }
            prev = ch;
        }
        result
    },
}

Symbol1: String = {
    r"[a-zA-Z0-9/_$@.]+" => <>.to_string(),
}