git-repo-manager 0.9.0

Manage multiple git repositories. You configure the git repositories in a file, the program does the rest!
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113

{
  description = "git-repo-manager";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs =
    {
      self,
      nixpkgs,
    }:
    let
      inherit (nixpkgs) lib;
      allSystems = [
        "x86_64-linux"
        "x86_64-darwin"
        "aarch64-linux"
        "aarch64-darwin"
      ];
      forAllSystems = function: lib.genAttrs allSystems (sys: function sys self.legacyPackages.${sys});
    in
    {
      overlays = {
        git-repo-manager = final: prev: {
          git-repo-manager = self.packages.${prev.stdenv.system}.default;
        };
      };

      legacyPackages = forAllSystems (system: _: import nixpkgs { inherit system; });

      apps = forAllSystems (
        system: _: {
          default = self.apps.${system}.git-repo-manager;

          git-repo-manager =
            let
              inherit (self.packages.${system}) git-repo-manager;
            in
            {
              type = "app";
              inherit (git-repo-manager) meta;
              program = lib.getExe git-repo-manager;
            };
        }
      );

      checks = forAllSystems (
        system: _: {
          pkg = self.packages.${system}.default;
          shl = self.devShells.${system}.default;
        }
      );

      devShells = forAllSystems (
        system: pkgs: {
          default = pkgs.mkShell {
            buildInputs = [
              self.packages.${pkgs.system}.default
            ]
            ++ (with pkgs; [
              black
              isort
              just
              mdbook
              nixfmt-classic # nix formatting
              python3
              ruff
              shellcheck
              shfmt
            ]);
          };
        }
      );

      packages = forAllSystems (
        system: pkgs: {
          default = self.packages.${system}.git-repo-manager;

          git-repo-manager = pkgs.rustPlatform.buildRustPackage {
            name = "grm"; # otherwise `nix run` looks for git-repo-manager
            src = ./.;

            cargoLock.lockFile = ./Cargo.lock;

            nativeBuildInputs = [ pkgs.pkg-config ];
            buildInputs = with pkgs; [
              # deps
              git
              openssl
              openssl.dev
              zlib
              zlib.dev
            ];
            meta = {
              description = "A git tool to manage worktrees and integrate with GitHub and GitLab";
              longDescription = ''
                GRM helps you manage git repositories in a declarative way. Configure your repositories in a TOML or YAML file, GRM does the rest.

                Also, GRM can be used to work with git worktrees in an opinionated, straightforward fashion.
              '';

              homepage = "https://hakoerber.github.io/git-repo-manager/";
              license = lib.licenses.gpl3Plus;
              mainProgram = "grm";
              maintainers = with lib.maintainers; [ siriobalmelli ];
              platforms = lib.platforms.all;
            };
          };
        }
      );
    };
}