g1-common 0.1.0-alpha.3

Common types and traits between the client and server portion of the G1 graph store.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170

use crate::{
	command::Command,
	lexer::{parse_stringish, Token},
	query::{Clause, Predicate, Query, Value},
};

grammar<'src>;

U32: u32 = U32Tok =>? {
	<>.1.parse().map_err(|e: std::num::ParseIntError| {
		lalrpop_util::ParseError::User { error: e.to_string() }
	})
};
String: String = StringTok => parse_stringish(<>.1);

Var: String = {
	EscapedVar => parse_stringish(<>.1),
	UnescapedVar => <>.1.to_string(),
};

pub Value: Value = {
	String => Value::Str(<>),
	Var => Value::Var(<>),
};

Values: Vec<Value> = {
	")" => Vec::new(),
	"," <head: Value> <tail: Values> => {
		let mut tail = tail;
		tail.push(head);
		tail
	},
};

pub Predicate: Predicate = {
	<name: Var> "(" ")" => Predicate { name, args: Vec::new() },
	<name: Var> "(" <head: Value> <tail: Values> => {
		let mut args = tail;
		args.push(head);
		args.reverse();
		Predicate { name, args }
	},
};

Predicates: Vec<(bool, Predicate)> = {
	"." => Vec::new(),
	"," <head: Predicate> <tail: Predicates> => {
		let mut tail = tail;
		tail.push((false, head));
		tail
	},
	"," "!" <head: Predicate> <tail: Predicates> => {
		let mut tail = tail;
		tail.push((true, head));
		tail
	},
};

pub Clause: Clause = {
	<head: Predicate> "." => Clause { head, body: Vec::new() },
	<head: Predicate> ":-" <head_body: Predicate> <tail_body: Predicates> => {
		let mut body = tail_body;
		body.push((false, head_body));
		body.reverse();
		Clause { head, body }
	},
	<head: Predicate> ":-" "!" <head_body: Predicate> <tail_body: Predicates> => {
		let mut body = tail_body;
		body.push((true, head_body));
		body.reverse();
		Clause { head, body }
	},
};

Clauses: Vec<Clause> = {
	=> Vec::new(),
	<init: Clauses> <tail: Clause> => {
		let mut body = init;
		body.push(tail);
		body
	},
};

pub Query: Query = {
	<clauses: Clauses> "?-" <goal: Predicate> "." => Query { clauses, goal },
};

pub Command: Command = {
	<Clause> => Command::Clause(<>),

	".create_atom" => Command::CreateAtom,
	".delete_atom" <atom: String> => Command::DeleteAtom(atom),

	".create_name" <atom: String> <ns: String> <title: String> => {
		Command::CreateName(atom, ns, title, false)
	},
	".delete_name" <ns: String> <title: String> => Command::DeleteName(ns, title),
	".upsert_name" <atom: String> <ns: String> <title: String> => {
		Command::CreateName(atom, ns, title, true)
	},

	".create_edge" <from: String> <to: String> <label: String> => {
		Command::CreateEdge(from, to, label)
	},
	".delete_edge" <from: String> <to: String> <label: String> => {
		Command::DeleteEdge(from, to, label)
	},

	".create_tag" <atom: String> <key: String> <value: String> => {
		Command::CreateTag(atom, key, value, false)
	},
	".delete_tag" <atom: String> <key: String> => {
		Command::DeleteTag(atom, key)
	},
	".upsert_tag" <atom: String> <key: String> <value: String> => {
		Command::CreateTag(atom, key, value, true)
	},

	".create_blob" <atom: String> <kind: String> <mime: String> <hash: String> => {
		Command::CreateBlob(atom, kind, mime, hash, false)
	},
	".delete_blob" <atom: String> <kind: String> <mime: String> => {
		Command::DeleteBlob(atom, kind, mime)
	},
	".upsert_blob" <atom: String> <kind: String> <mime: String> <hash: String> => {
		Command::CreateBlob(atom, kind, mime, hash, true)
	},

	"?-" <Predicate> "." => Command::Query(<>),
    ".help" => Command::Help,
    ".list" => Command::List,
	".quit" => Command::Quit,
	".undefine" <name: Var> "/" <argn: U32> => Command::Undefine(name, argn),
};

extern {
	type Error = String;

	enum (Token, &'src str) {
		")" => (Token::ParenClose, _),
		"(" => (Token::ParenOpen, _),
		"." => (Token::Period, _),
		"," => (Token::Comma, _),
		"/" => (Token::Slash, _),
		"?-" => (Token::Query, _),
		":-" => (Token::Turnstile, _),
		"!" => (Token::Not, _),
		".create_atom" => (Token::DotCreateAtom, _),
		".delete_atom" => (Token::DotDeleteAtom, _),
		".create_name" => (Token::DotCreateName, _),
		".delete_name" => (Token::DotDeleteName, _),
		".upsert_name" => (Token::DotUpsertName, _),
		".create_edge" => (Token::DotCreateEdge, _),
		".delete_edge" => (Token::DotDeleteEdge, _),
		".create_tag" => (Token::DotCreateTag, _),
		".delete_tag" => (Token::DotDeleteTag, _),
		".upsert_tag" => (Token::DotUpsertTag, _),
		".create_blob" => (Token::DotCreateBlob, _),
		".delete_blob" => (Token::DotDeleteBlob, _),
		".upsert_blob" => (Token::DotUpsertBlob, _),
		".help" => (Token::DotHelp, _),
		".list" => (Token::DotList, _),
		".quit" => (Token::DotQuit, _),
		".undefine" => (Token::DotUndefine, _),
		U32Tok => (Token::U32, _),
		StringTok => (Token::String, _),
		EscapedVar => (Token::EscapedVar, _),
		UnescapedVar => (Token::Var, _),
	}
}