ftrace 0.2.1

ftrace - trace files and paths
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103

// Meta

WHITESPACE = _{ " " | "\t" | "\r" | "\n" }
COMMENT = _{ "/*" ~ (comment_inner)? ~ "*/" }
comment_inner = @{ (!"*/" ~ ANY)* }

// As value primitives

null = { "NULL" }

// Numbers

number_hex = _{ "0x" ~ ASCII_HEX_DIGIT+ }
number_oct = _{ "0" ~ ASCII_OCT_DIGIT+ }
number = @{
  number_hex | number_oct | "-"? ~ ("0" | ASCII_NONZERO_DIGIT ~ ASCII_DIGIT*) ~ ("." ~ ASCII_DIGIT*)?
}

// Identifiers and expressions

constant = @{ (ASCII_ALPHA_UPPER)+ }
ident = @{ !("NULL") ~ (ASCII_ALPHA ~ (ASCII_ALPHANUMERIC | "_")*) }
op = @{ "|" | "&" | "or" }
expr = { (call | ident | number) ~ (op ~ (call | ident | number))* }

// Strings

char = {
      !("\"" | "\\") ~ ANY
    | "\\" ~ ("\"" | "\\" | "/" | "b" | "f" | "n" | "r" | "t" | "x")
    | "\\" ~ ("u" ~ ASCII_HEX_DIGIT{4})
}

string_inner = @{ char* }
string = ${ "\"" ~ string_inner ~ "\"" ~ ("...")? }

// Lists

list = { "{" ~ (value)* ~ "..."? ~ "}" }

// Arrays

array = {
    "[" ~ "]"
  | "[" ~ value ~ ("," ~ value)* ~ "]"
}

// Bit sets

bit_set = {
    "~[" ~ "]"
  | "~"? ~ "[" ~ constant ~ (constant)* ~ "]"
}

// Maps

key_value = { ident ~ "=" ~ ("..." | value) }
hash = {
    "{" ~ ("...")? ~ "}"
  | "{" ~ key_value ~ ("," ~ key_value)* ~ ("...")? ~ "}"
  | "{" ~ key_value ~ ("," ~ key_value)* ~ "," ~ ("...")? ~ "}"
}

// Calls

call_info = { (ANY)+ }
call_result = { "=" ~ number ~ call_info? }
call = {
    ident ~ "(" ~ ")" ~ call_result?
  | ident ~ "(" ~ value ~ ("," ~ value)* ~ ")" ~ call_result?
  | ident ~ "(" ~ value ~ ("," ~ value)* ~ "," ~ ")" ~ call_result?
}

// Prefixes

pid = { "[pid" ~ number ~ "]" }

timestamp = { number }

// Recursive values

value = _{ expr | call | hash | bit_set | array | list | string | ident | number | null }

// Root level

exit = { "+++ exited with" ~ number ~ "+++" }
kill = { "+++ killed by" ~ constant ~ "+++" }
signal = { "---" ~ constant ~ hash? ~ "..."? ~ "---" }
permission_denied = { (!":" ~ ANY)+ ~ ":" ~ "attach:" ~ "ptrace(PTRACE_SEIZE," ~ number ~ "):" ~ "Operation not permitted" }
process_attach = { (!":" ~ ANY)+ ~ ":" ~ "Process" ~ number ~ "attached" }
process_detach = { "strace:" ~ "Process" ~ number ~ "detached" }
trace = _{ (pid)? ~ (timestamp)? ~ (call | exit | kill) }
line = {
    trace
  | signal
  | permission_denied
  | process_attach
  | process_detach
}

// Entry point

strace = _{ SOI ~ line ~ EOI }