ftml 1.30.0

Foundation Text Markup Language - a library to render Wikidot text as HTML
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

//
// include/grammar.pest
//
// ftml - Library to parse Wikidot text
// Copyright (C) 2019-2025 Wikijump Team
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU Affero General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU Affero General Public License for more details.
//
// You should have received a copy of the GNU Affero General Public License
// along with this program. If not, see <http://www.gnu.org/licenses/>.
//

// A simple parser generation exclusively to extract [[include]] directives
// within the wikitext. Other elements should be ignored and left as-is.

// Wikidot's "include" rule has some strange logic:
//
// [[include]]s can have leading *and* trailing pipe separators,
// for instance [[include page | a = 1 ]] or [[include page a = 1 | ]] (or both)
//
// Additionally, each argument must be separated from each other with a pipe.
// We encapsulate this logic by essentially doing "(parameter ~ pipe)* ~ (parameter ~ pipe?)?
// That is, all internal parameters need pipes inside, but the last does not,
// and is optional should the sequence end in a pipe.

// Normal version ([[include]] only)
include_normal = {
    SOI ~ // Because we slice from the start of an include block using regex
    "[[" ~ space? ~ ^"include" ~ space ~
    page_ref ~ space? ~
    ("|" ~ space?)? ~
    (argument ~ space? ~ "|" ~ space?)* ~
    (argument ~ space? ~ "|"?)? ~
    space? ~ include_end
}

// Compatibility version (accepts [[include]] too)
include_compatibility = {
    SOI ~ // Because we slice from the start of an include block using regex
    "[[" ~ space? ~ (^"include" | ^"include") ~ space ~
    page_ref ~ space? ~
    ("|" ~ space?)? ~
    (argument ~ space? ~ "|" ~ space?)* ~
    (argument ~ space? ~ "|"?)? ~
    space? ~ include_end
}

include_end = _{
    "]]" ~ &(NEWLINE | EOI)
}

argument = {
    identifier ~ space? ~
    "=" ~ space? ~
    value
}

value = {
    (!(include_end | "|") ~ ANY)+
}

// Reference to a page, possibly not on this wiki

page_ref = {
    (":" ~ site_name ~ ":")? ~ page_name
}
site_name = _{ (!(" " | "\n" | "\t" | "[" | "|" | "]" | ":") ~ ANY)+ }
page_name = _{ (!(" " | "\n" | "\t" | "[" | "|" | "]") ~ ANY)+ }

// Helpers

identifier = { (ASCII_ALPHANUMERIC | "-" | "_")+ }
space = _{ (" " | "\n" | "\t")+ }

// vim: set fdm=marker foldlevel=0: