frust-engine 0.6.0

Sparse-strip GPU render pipeline for Frust: compiles a scene display list into strips and records the draw passes on wgpu.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

// Copyright 2026 the Vello Authors
// SPDX-License-Identifier: Apache-2.0 OR MIT

// Derived from vello_sparse_shaders 0.2.0 (`shaders/copy.wesl`); its
// `import package::helpers::...` lines are resolved by prepending
// `helpers.wgsl` at load time (`gpu::shader_src`).
//
// Copies rectangular regions between intermediate textures, one instance per
// region.

// Must stay byte-compatible with the copy-instance vertex layout in
// `gpu::pipelines`.
struct CopyInstance {
    // Origin in the destination texture page, packed as u16s.
    @location(0)
    dest_texture_origin: u32,
    // Origin in the source texture page, packed as u16s.
    @location(1)
    source_texture_origin: u32,
    // Width and height of the copied region, packed as u16s.
    @location(2)
    copy_rect_size: u32,
    // Width and height of the destination texture page, packed as u16s.
    @location(3)
    dest_texture_size: u32,
}

struct VertexOutput {
    @location(0)
    source_texture_xy: vec2<f32>,
    @builtin(position)
    position: vec4<f32>,
}

@group(0) @binding(0)
var source_texture: texture_2d<f32>;

@vertex
fn vs_main(
    @builtin(vertex_index) vertex_index: u32,
    instance: CopyInstance,
) -> VertexOutput {
    let dest_texture_origin = unpack_u16_pair(instance.dest_texture_origin);
    let source_texture_origin = unpack_u16_pair(instance.source_texture_origin);
    let copy_rect_size = unpack_u16_pair(instance.copy_rect_size);
    let dest_texture_size = unpack_u16_pair(instance.dest_texture_size);

    let local = quad_corner(vertex_index) * vec2<f32>(copy_rect_size);
    let dest_texture_xy = vec2<f32>(dest_texture_origin) + local;

    var out: VertexOutput;
    out.source_texture_xy = vec2<f32>(source_texture_origin) + local;

    let ndc = pixel_to_ndc(dest_texture_xy, vec2<f32>(dest_texture_size));
    out.position = vec4<f32>(ndc, 0.0, 1.0);
    return out;
}

@fragment
fn fs_main(
    @location(0) source_texture_xy: vec2<f32>,
) -> @location(0) vec4<f32> {
    return textureLoad(source_texture, vec2<i32>(source_texture_xy), 0);
}