foxmark3 0.1.1

Send/receive Proxmark 3 commands
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91

{
  description = "An easy and robust event check-in system built atop a Proxmark 3 and set of pre-existing ISO/IEC 14443-3 compliant RFID cards";
  inputs = {
    flake-parts.url = "github:hercules-ci/flake-parts";
    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";

    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    pre-commit-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs =
    inputs@{
      flake-parts,
      pre-commit-hooks,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [ "x86_64-linux" ];
      perSystem =
        { pkgs, system, ... }:
        let
          rust = pkgs.rust-bin.stable.latest;
          check = pre-commit-hooks.lib.${system}.run {
            src = ./.;
            hooks = {
              deadnix = {
                enable = true;
                args = [ "--no-lambda-pattern-names" ];
              };
              nixfmt-rfc-style.enable = true;
              statix.enable = true;

              cargo-check.enable = true;
              rustfmt.enable = true;
            };
          };

          buildDeps = [
            pkgs.pkg-config
          ];
          runtimeDeps = [
            pkgs.systemd
          ];
          devDeps = [
            pkgs.bacon
            pkgs.proxmark3
          ];

          alipad = builtins.fromTOML (builtins.readFile ./Cargo.toml);
        in
        {
          _module.args.pkgs = import inputs.nixpkgs {
            inherit system;
            overlays = [ (import inputs.rust-overlay) ];
          };

          checks.pre-commit-check = check;

          packages.default =
            (pkgs.makeRustPlatform {
              cargo = rust.minimal;
              rustc = rust.minimal;
            }).buildRustPackage
              {
                inherit (alipad.package) name version;
                src = ./.;
                cargoLock.lockFile = ./Cargo.lock;
                buildInputs = runtimeDeps;
                nativeBuildInputs = buildDeps;
              };

          devShells.default =
            pkgs.mkShell.override
              {
                stdenv = pkgs.stdenvAdapters.useMoldLinker pkgs.clangStdenv;
              }
              {
                shellHook = check.shellHook + ''
                  export RUST_SRC_PATH=${pkgs.rustPlatform.rustLibSrc}
                '';
                buildInputs = runtimeDeps ++ check.enabledPackages;
                nativeBuildInputs = buildDeps ++ devDeps ++ [ rust.default ];
              };
        };
    };
}