formatjs_cli 1.1.10

Command-line interface for FormatJS - A Rust-based CLI for internationalization
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

load("@with_cfg.bzl", "with_cfg")

_HOSTS = [
    "linux_aarch64",
    "linux_x86_64",
    "macos_aarch64",
    "macos_x86_64",
    "windows_aarch64",
    "windows_x86_64",
]

def _llvm_toolchains(target):
    return [
        Label("@llvm_toolchains//:bootstrap_%s_to_%s" % (host, target))
        for host in _HOSTS
    ] + [
        Label("@llvm_toolchains//:%s_to_%s" % (host, target))
        for host in _HOSTS
    ]

def _release_binary(platform, llvm_target = None):
    builder = with_cfg(
        native.genrule,
    ).set(
        "compilation_mode",
        "opt",
    ).set(
        "platforms",
        [Label(platform)],
    )
    if llvm_target:
        builder = builder.extend(
            "extra_toolchains",
            _llvm_toolchains(llvm_target),
        ).set(
            Label("@llvm//config:experimental_stub_libgcc_s"),
            True,
        ).set(
            Label("@llvm//config/bootstrap:experimental_stub_libgcc_s"),
            True,
        )
    return builder.build()

release_binary_darwin_arm64, _release_binary_darwin_arm64_internal = _release_binary(
    "//crates/formatjs_cli/platforms:darwin_arm64",
    "macos_aarch64",
)

release_binary_linux_x64, _release_binary_linux_x64_internal = _release_binary(
    "//crates/formatjs_cli/platforms:linux_x86_64_musl",
    "linux_x86_64",
)

release_binary_linux_arm64, _release_binary_linux_arm64_internal = _release_binary(
    "//crates/formatjs_cli/platforms:linux_aarch64_musl",
    "linux_aarch64",
)

release_binary_linux_x64_gnu, _release_binary_linux_x64_gnu_internal = _release_binary(
    "//crates/formatjs_cli/platforms:linux_x86_64",
    "linux_x86_64",
)

release_binary_linux_arm64_gnu, _release_binary_linux_arm64_gnu_internal = _release_binary(
    "//crates/formatjs_cli/platforms:linux_aarch64",
    "linux_aarch64",
)

release_binary_windows_x64, _release_binary_windows_x64_internal = _release_binary(
    "//crates/formatjs_cli/platforms:windows_x86_64_msvc",
)

release_binary_windows_x64_gnullvm, _release_binary_windows_x64_gnullvm_internal = _release_binary(
    "//crates/formatjs_cli/platforms:windows_x86_64_gnullvm",
    "windows_x86_64",
)