fork-manager 0.4.1

Automatize your fork
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

{
  darwin,
  installShellFiles,
  lib,
  mainProgram ? "fork-manager",
  pkg-config,
  rustPlatform,
  stdenv,
}:

rustPlatform.buildRustPackage {
  pname = "fork-manager";
  version = "0.4.1";

  src = lib.fileset.toSource {
    root = ./.;
    fileset = lib.fileset.unions [
      ./Cargo.lock
      ./Cargo.toml
      ./src
      ./tests
    ];
  };

  cargoLock.lockFile = ./Cargo.lock;

  buildInputs = lib.optional stdenv.isDarwin darwin.apple_sdk.frameworks.Security;

  nativeBuildInputs = [
    installShellFiles
    pkg-config
  ];

  checkFlags = [
    # This require network access
    "--skip=pr_to_change"
  ];

  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
    installShellCompletion --cmd fork-manager \
      --bash <($out/bin/${mainProgram} --generate bash) \
      --fish <($out/bin/${mainProgram} --generate fish) \
      --zsh <($out/bin/${mainProgram} --generate zsh)
  '';

  meta = {
    inherit mainProgram;
    description = "Automatize your fork";
    homepage = "https://github.com/nim65s/fork-manager";
    changelog = "https://github.com/nim65s/fork-manager/blob/main/CHANGELOG.md";
    license = with lib.licenses; [
      asl20
      mit
    ];
    maintainers = with lib.maintainers; [ nim65s ];
  };
}