forgefix 0.3.0

ForgeFIX is an opinionated FIX 4.2 client library for the buy-side written in Rust. ForgeFIX is optimized for the subset of the FIX protocol used by buy-side firms connecting to brokers and exchanges for communicating orders and fills.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" omit-xml-declaration="yes" />
<xsl:template match="/">
#![allow(non_camel_case_types, dead_code)]
#![allow(clippy::upper_case_acronyms)]

use crate::fix::decode::DecodeError; 

<xsl:apply-templates />
</xsl:template>

<xsl:template match="/fix/messages">
    pub fn is_session_message(msg_type: char) -> bool{
        matches!(msg_type,
   <xsl:for-each select="message[@msgcat='admin']">'<xsl:value-of select="@msgtype"/>' <xsl:if test="position() != last()"> <xsl:text>|</xsl:text> </xsl:if> </xsl:for-each>
        )
    }
</xsl:template>

<xsl:template match="/fix/fields">
#[repr(C)]
#[derive(Debug)]
pub enum Tags {
   <xsl:for-each select="field"><xsl:value-of select="@name"/> = <xsl:value-of select="@number"/>,</xsl:for-each>
}
impl TryFrom&lt;u32&gt; for Tags {
    type Error = DecodeError;
    fn try_from(u : u32) -> Result&lt;Self, Self::Error&gt; {
    match u {
    <xsl:for-each select="field"><xsl:value-of select="@number"/> => Ok(Tags::<xsl:value-of select="@name"/>),</xsl:for-each>
    _=> Err(DecodeError::UnknownTag(u)), 
        }
    }
}
impl From&lt;Tags&gt; for u32 {
    fn from(value: Tags) -> u32 {
        value as isize as u32
    }
}


pub fn get_data_ref(tag: u32) -> Option&lt;u32&gt; {
match tag {
<xsl:for-each select="./field[@type = 'DATA']">
    <xsl:variable name="siblingXpath" select="../field[@name = concat(current()/@name, 'Len') or @name = concat(current()/@name, 'Length')]" />
    <xsl:if test="$siblingXpath">
    <xsl:for-each select="$siblingXpath">
        <xsl:value-of select="@number"/><xsl:if test="position() != last()"> <xsl:text>|</xsl:text> </xsl:if>
    </xsl:for-each> => Some(<xsl:value-of select="@number"/>), 
    </xsl:if>
</xsl:for-each>
_=>None
}
}
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="/fix/fields/field[@type = 'CHAR' or @type = 'BOOLEAN'][value]">
#[repr(C)]
#[derive(Debug,PartialEq,Eq,Copy,Clone)]
pub enum <xsl:value-of select="./@name" /> {
    <xsl:for-each select="value">
    <xsl:value-of select="./@description"/> = '<xsl:value-of select="./@enum"/>' as isize,
    </xsl:for-each>
}

impl From&lt;<xsl:value-of select="./@name" />&gt; for char {
    fn from(a:<xsl:value-of select="./@name" />) -> char {
        a as isize as u8 as char
    }
}
<xsl:if test="*">
impl From&lt;<xsl:value-of select="./@name" />&gt; for &amp;'static [u8] {
    fn from(a:<xsl:value-of select="./@name" />) -> &amp;'static [u8] {
        match a {
    <xsl:for-each select="value">
    <xsl:value-of select="../@name"/>::<xsl:value-of select="./@description"/> => b"<xsl:value-of select="./@enum"/>",
    </xsl:for-each>
        }
    }
}

    <xsl:if test="*">
impl AsRef&lt;[u8]&gt; for <xsl:value-of select="./@name" /> {
    fn as_ref(&amp;self) -> &amp;[u8] {
        match self {
    <xsl:for-each select="value">
    <xsl:value-of select="../@name"/>::<xsl:value-of select="./@description"/> => b"<xsl:value-of select="./@enum"/>",
    </xsl:for-each>
        }
    }
}
</xsl:if>

impl TryFrom&lt;char&gt; for <xsl:value-of select="./@name" /> {
    type Error = DecodeError;
    fn try_from(c : char) -> Result&lt;Self, Self::Error&gt; {
    match c {
    <xsl:for-each select="value">'<xsl:value-of select="./@enum"/>' => Ok(Self::<xsl:value-of select="./@description"/>),</xsl:for-each>
    _=> Err(DecodeError::UnknownChar(Tags::<xsl:value-of select="./@name"/>, c)),
        }
    }
}
</xsl:if>
</xsl:template>

<xsl:template match="/fix/fields/field[@type = 'INT'][value]">
#[repr(C)]
#[derive(Debug,PartialEq,Eq,Copy,Clone)]
pub enum <xsl:value-of select="./@name" /> {
    <xsl:for-each select="value">
    <xsl:value-of select="./@description"/> = <xsl:value-of select="./@enum"/>,
    </xsl:for-each>
}
<xsl:if test="*">
impl TryFrom&lt;u8&gt; for <xsl:value-of select="./@name" /> {
    type Error = DecodeError;
    fn try_from(c : u8) -> Result&lt;Self, Self::Error&gt; {
    match c {
    <xsl:for-each select="value"><xsl:value-of select="./@enum"/> => Ok(Self::<xsl:value-of select="./@description"/>),</xsl:for-each>
    _=> Err(DecodeError::UnknownInt(Tags::<xsl:value-of select="./@name"/>, c)),
        }
    }
}
</xsl:if>
</xsl:template>

</xsl:stylesheet>