flk 0.6.3

A CLI tool for managing flake.nix devShell environments
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90

{
  nixpkgs,
  flake-utils,
  profile-lib,
}: {
  src,
  systems ? null,
  nixpkgsOverride ? null,
}: _inputs: let
  np =
    if nixpkgsOverride != null
    then nixpkgsOverride
    else nixpkgs;
  lib = np.lib;

  configPath = src + "/config.nix";
  config =
    if builtins.pathExists configPath
    then import configPath
    else {};
  defaultProfile = config.defaultProfile or "";
  maxCombinations = config.maxCombinations or 3;

  eachSystem =
    if systems == null
    then flake-utils.lib.eachDefaultSystem
    else flake-utils.lib.eachSystem systems;

  pinsPath = src + "/pins.nix";
  pinsData =
    if builtins.pathExists pinsPath
    then import pinsPath
    else {
      sources = {};
      pinnedPackages = {};
    };
  pins = pinsData.sources or {};
  pinnedPackages = pinsData.pinnedPackages or {};

  fetchPin = ref: builtins.getFlake ref;

  profilesDir = src + "/profiles";
in
  eachSystem (
    system: let
      rustOverlayList =
        if pins ? rust-overlay
        then [(fetchPin pins.rust-overlay).overlays.default]
        else [];

      createPinnedOverlays = pp:
        builtins.map (
          pinName: let
            pkgDefs = pp.${pinName};
            pinnedPkgs = (fetchPin pins.${pinName}).legacyPackages.${system};
          in
            _final: _prev:
              builtins.listToAttrs (
                builtins.map (pkgDef: {
                  name = pkgDef.name;
                  value = pinnedPkgs.${pkgDef.pkg};
                })
                pkgDefs
              )
        ) (builtins.attrNames pp);

      overlays = rustOverlayList ++ (createPinnedOverlays pinnedPackages);

      pkgs = import np {
        inherit system overlays;
      };

      profileLib = profile-lib.lib {inherit pkgs;};

      profileFiles = builtins.readDir profilesDir;
      profileDefinitions = builtins.listToAttrs (
        map (file: {
          name = lib.removeSuffix ".nix" file;
          value = import (profilesDir + "/${file}") {inherit pkgs system;};
        })
        (builtins.filter
          (n: n != "default.nix" && lib.hasSuffix ".nix" n)
          (builtins.attrNames profileFiles))
      );
    in
      profileLib.mkProfileOutputs {
        inherit profileDefinitions maxCombinations;
      }
      // lib.optionalAttrs (defaultProfile != "") {defaultShell = defaultProfile;}
  )