fidget-wgpu 0.5.0

WGPU backend for Fidget
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125

struct BlurConfig {
    /// Image size, in pixels
    image_size: vec2u,

    /// Blur radius, also in pixels
    radius: u32,

    // Padding to 16 bytes
    _pad: u32,
}

@group(0) @binding(0) var<uniform> config: BlurConfig;
@group(0) @binding(1) var<storage, read> image: array<f32>;
@group(0) @binding(2) var<storage, read_write> out: array<f32>;

@compute @workgroup_size(8, 8)
fn blur_main(
    @builtin(global_invocation_id) global_id: vec3u
) {
    // Clamp to image size
    if global_id.x >= config.image_size.x ||
       global_id.y >= config.image_size.y
    {
        return;
    }
    let i = global_id.x + global_id.y * config.image_size.x;

    // Propagate empty pixels
    if image[i] < 0.0 {
        out[i] = -1.0;
        return;
    }

    // This is a Kuwahara-style edge-preserving filter: we find a value + score
    // across four quadrants, then pick the best one.
    let a = blur_at(
        i32(global_id.x) - i32(config.radius),
        i32(global_id.y) - i32(config.radius),
    );
    let b = blur_at(
        i32(global_id.x),
        i32(global_id.y) - i32(config.radius),
    );
    let c = blur_at(
        i32(global_id.x) - i32(config.radius),
        i32(global_id.y),
    );
    let d = blur_at(
        i32(global_id.x),
        i32(global_id.y),
    );

    var best = a;
    best = merge(best, b);
    best = merge(best, c);
    best = merge(best, d);

    if best.valid {
        out[i] = best.mean;
    } else {
        out[i] = image[i]; // guaranteed to be non-empty
    }
}

fn merge(best: BlurOutput, other: BlurOutput) -> BlurOutput {
    if !best.valid || (other.valid && other.score < best.score) {
        return other;
    } else {
        return best;
    }
}

struct BlurOutput {
    mean: f32,
    score: f32,
    valid: bool,
}

fn blur_at(x: i32, y: i32) -> BlurOutput {
    // Find the average value in a square with corner [x, y]
    var sum = 0.0;
    var count = 0.0;
    for (var i = 0u; i <= config.radius; i += 1) {
        for (var j = 0u; j <= config.radius; j += 1) {
            let tx = x + i32(i);
            let ty = y + i32(j);
            if tx >= 0 && ty >= 0 &&
                u32(tx) < config.image_size.x &&
                u32(ty) < config.image_size.y
            {
                let s = image[u32(tx) + u32(ty) * config.image_size.x];
                if s >= 0.0 {
                    sum += s;
                    count += 1.0;
                }
            }
        }
    }

    // Only count squares with a sufficient number of valid pixels
    if count < f32(config.radius * config.radius) * 0.5 {
        return BlurOutput(0.0, 0.0, false);
    }
    let mean = sum / count;
    var stdev = 0.0;

    // Find the standard deviation of that square patch
    for (var i = 0u; i <= config.radius; i += 1) {
        for (var j = 0u; j <= config.radius; j += 1) {
            let tx = x + i32(i);
            let ty = y + i32(j);
            if tx >= 0 && ty >= 0 &&
                u32(tx) < config.image_size.x &&
                u32(ty) < config.image_size.y
            {
                let s = image[u32(tx) + u32(ty) * config.image_size.x];
                if s >= 0.0 {
                    stdev += pow(mean - s, 2);
                }
            }
        }
    }

    return BlurOutput(mean, stdev / count, true);
}