ferronconf 0.4.0

A Rust library for parsing `ferron.conf` configuration files — a domain-specific language for Ferron web server configurations.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105

/* whitespace and line continuations are discarded by a lexer */

config          ::= ( ';' | statement )* EOF

statement       ::= directive
                  | host-block
                  | match-block
                  | global-block
                  | snippet-block

directive       ::= identifier value* block?

block           ::= '{' ( ';' | statement )* '}'

host-block      ::= host-pattern ( ',' host-pattern )* block
                  /* only allowed at top level */

global-block    ::= block
                  /* only allowed at top level */

snippet-block   ::= 'snippet' identifier block

match-block     ::= 'match' identifier matcher-block

matcher-block   ::= '{' (';' | matcher-expression)* '}'

matcher-expression
                ::= operand operator operand

operand         ::= identifier-path
                  | string
                  | number

value           ::= string
                  | number
                  | boolean
                  | interpolation

interpolation   ::= '{{' identifier-path '}}'

identifier-path ::= identifier ( '.' identifier )*

operator        ::= '=='
                  | '!='
                  | '~'
                  | '!~'
                  | 'in'

host-pattern    ::= protocol? host ( ':' port )?

protocol        ::= identifier | bare-string

host            ::= '*'
                  | hostname
                  | ipv4
                  | '[' ipv6 ']'

hostname        ::= host-label ( '.' host-label )*

host-label      ::= identifier
                  | '*'

ipv4            ::= dec-octet '.' dec-octet '.' dec-octet '.' dec-octet
dec-octet       ::= DIGIT+   /* validated 0–255 by parser */

ipv6            ::= ipv6-hex ( ':' ipv6-hex )*  /* validated by parser */
ipv6-hex         ::= ( DIGIT | [A-Fa-f] )*

port            ::= DIGIT+

string          ::= quoted-string
                  | raw-string
                  | bare-string

quoted-string   ::= '"' quoted-char* '"'

quoted-char     ::= [^"\\]
                  | '\\' .

raw-string      ::= 'r' '"' raw-char* '"'

raw-char        ::= [^"]

bare-string     ::= bare-char+

/* any character except whitespace, braces, quotes, hash, comma, and semicolon */
/* Note: [ and ] are structural at line start (IPv6), but part of bare strings elsewhere */
bare-char       ::= [^?"{}",;#\n\r\t ]

/* commas and semicolons between tokens are discarded, serving as optional delimiters */

identifier      ::= ALPHA ( ALPHA | DIGIT | '_' | '-' )*

boolean         ::= 'true'
                  | 'false'

number          ::= ( '-' | '+' )? DIGIT+ ( '.' DIGIT+ )?

/* comments and line continuations are discarded by a lexer. */
/* a line continuation is `\` followed by optional comment + newline */
comment         ::= '#' comment-char*
comment-char    ::= . - ( '\r' | '\n' )

ALPHA           ::= [A-Za-z]
DIGIT           ::= [0-9]