fall 0.1.2

An easily embeddable, futures-friendly logic engine.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

use cst::*;

#[LALR]
grammar;

Separated<Item, Sep, T>: Vec<T> = {
    <i:Separated<Item, Sep, T>> Sep <l:Item> => {
        let mut i = i;
        i.push(l);
        i
    },
    Item => vec![<>],
};

////////////////////////////////////////////////////////////////////////////////////////////////////

Atom: String = {
    r"[a-z.][A-Za-z0-9_.]*" => <>.to_string(),
    <s:r"'[^']*'"> => s[1..s.len()-1].to_string(),
    <s:r#""[^"]*""#> => s[1..s.len()-1].to_string(),
};

pub Clause: Clause = {
    <h:Lit> "." => Clause(h, vec![]),
    <h:Lit> ":-" <t:Separated<Lit, ",", Lit>> "." => Clause(h, t),
};

pub Lit: Lit = {
    Atom => Lit(<>, vec![]),
    <a:Atom> "(" <ts:Separated<Term, ",", Term>> ")" => Lit(a, ts),
};

pub Rules: Rules = {
    Clause* => Rules(<>),
};

pub Term: Term = {
    "_"                       => Term::Any,
    Lit                       => Term::Lit(<>),
    r"[0-9]+"                 => Term::Num(<>.parse().unwrap()),
    r"[A-Z_][A-Za-z0-9_]*" => Term::Var(<>.to_string()),
};