facti-lib 0.2.1

Facti common library
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

WHITESPACE = _{ " " }

not_newline = _{ !NEWLINE ~ ANY }

section_start = _{ "-"{99} }

major = { ASCII_DIGIT+ }
minor = { ASCII_DIGIT+ }
patch = { ASCII_DIGIT+ }
version = ${ major ~ "." ~ minor ~ "." ~ patch }
version_line = _{ "Version: " ~ version }

date = { not_newline+ }
date_line = _{ "Date: " ~ date }

heading = { (!":" ~ ANY | ":" ~ !NEWLINE)+ }
heading_line = _{ "  " ~ heading ~ ":" }

entry_prefix = _{ " "{4} ~ "- " }
entry_sub_prefix = _{ " "{6} }
entry_line = @{ not_newline+ }
entry_additional = _{ entry_sub_prefix ~ entry_line }
entry = ${ entry_prefix ~ entry_line ~ (NEWLINE+ ~ entry_additional)* }

category = ${ heading_line ~ (NEWLINE+ ~ entry)+ }
categories = _{ category ~ (NEWLINE+ ~ category)* }

section = ${
	section_start ~ NEWLINE ~ version_line ~
    (NEWLINE+ ~ date_line)? ~
    (NEWLINE+ ~ categories)?
}

changelog = { SOI ~ section? ~ (NEWLINE+ ~ section)* ~ (WHITESPACE | NEWLINE)* ~ EOI }