emlite 0.1.54

A Rust wrapper around emlite
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

cmake_minimum_required(VERSION 3.20)
project(emsenv VERSION 0.1.3 LANGUAGES C)

add_library(emsenv src/lib.c)
set_target_properties(emsenv PROPERTIES LINKER_LANGUAGE C)
add_library(emsenv::emsenv ALIAS emsenv)

include(GNUInstallDirs)

set(emsenv_INSTALL_CMAKEDIR "${CMAKE_INSTALL_LIBDIR}/cmake/emsenv")

install(
  TARGETS emsenv
  EXPORT  emsenvTargets
)

install(
  EXPORT      emsenvTargets
  FILE        emsenvTargets.cmake
  NAMESPACE   emsenv::
  DESTINATION "${emsenv_INSTALL_CMAKEDIR}"
)

include(CMakePackageConfigHelpers)

configure_package_config_file(
  "${CMAKE_CURRENT_LIST_DIR}/cmake/emsenvConfig.cmake.in"
  "${CMAKE_CURRENT_BINARY_DIR}/emsenvConfig.cmake"
  INSTALL_DESTINATION "${emsenv_INSTALL_CMAKEDIR}"
  NO_CHECK_REQUIRED_COMPONENTS_MACRO
)

write_basic_package_version_file(
  "${CMAKE_CURRENT_BINARY_DIR}/emsenvConfigVersion.cmake"
  VERSION       ${PROJECT_VERSION}
  COMPATIBILITY SameMajorVersion
)

install(
  FILES
    "${CMAKE_CURRENT_BINARY_DIR}/emsenvConfig.cmake"
    "${CMAKE_CURRENT_BINARY_DIR}/emsenvConfigVersion.cmake"
  DESTINATION "${emsenv_INSTALL_CMAKEDIR}"
)