dynify 0.1.1

Add dyn compatible variant to your async trait
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      rust-overlay,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ rust-overlay.overlays.default ];
        };
        inherit (pkgs) lib mkShellNoCC rust-bin;

        rustupToolchain = (lib.importTOML ./rust-toolchain.toml).toolchain;
        crateMetadata = (lib.importTOML ./Cargo.toml).package;

        # Rust toolchain for development
        rust-dev = rust-bin.fromRustupToolchain rustupToolchain;
        rust-dev-with-rust-analyzer = rust-dev.override (prev: {
          extensions = prev.extensions ++ [
            "rust-src"
            "rust-analyzer"
          ];
        });

        # Rust toolchain of MSRV
        rust-msrv = rust-bin.fromRustupToolchain {
          channel = crateMetadata.rust-version;
          profile = "minimal";
        };

        mkDevShell =
          devPkgs:
          (mkShellNoCC {
            packages =
              with pkgs;
              [
                # Necessary packages for build
                openssl
                cargo-binutils
              ]
              ++ devPkgs;
          });
      in
      {
        packages.default = pkgs.rustPlatform.buildRustPackage {
          pname = crateMetadata.name;
          version = crateMetadata.version;
          src = ./.;
          cargoLock.lockFile = ./Cargo.lock;
          meta = {
            description = crateMetadata.description;
            homepage = crateMetadata.repository;
            license = with lib.licenses; [
              mit
              asl20
            ];
          };
        };

        # The default devShell with IDE integrations
        devShells.default = mkDevShell [ rust-dev-with-rust-analyzer ];
        # A minimal devShell without IDE integrations
        devShells.minimal = mkDevShell [ rust-dev ];
        # A minimal devShell with toolchain of MSRV
        devShells.msrv = mkDevShell [ rust-msrv ];
      }
    );
}