dtrace-parser 0.3.0

Parse DTrace provider definitions into Rust
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

// A definition of the basic grammar of DTrace provider definitions.
// Copyright 2022 Oxide Computer Company

// Some basic tokens
PROBE_KEY = @{ "probe" }
PROVIDER_KEY = @{ "provider" }
SEMICOLON = @{ ";" }
LEFT_PAREN = @{ "(" }
RIGHT_PAREN = @{ ")" }
LEFT_BRACE = @{ "{" }
RIGHT_BRACE = @{ "}" }

// A valid identifier for a provider or probe
IDENTIFIER = @{ ASCII_ALPHA+ ~ (ASCII_ALPHANUMERIC | "_")* }

// Data types
BIT_WIDTH = @{ "8" | "16" | "32" | "64" }
PTR_T = @{ "ptr" }
SIGNED_INT = ${ "int" ~ (BIT_WIDTH | PTR_T) ~ "_t" }
UNSIGNED_INT = ${ "uint" ~ (BIT_WIDTH | PTR_T) ~ "_t" }
INTEGER = ${ (SIGNED_INT | UNSIGNED_INT) }
STAR = ${ "*" }
INTEGER_POINTER = ${ INTEGER ~ STAR }
STRING = { "char" ~ STAR }
DATA_TYPE = { INTEGER_POINTER | INTEGER | STRING }

// A list of probe arguments, which are just data types
ARGUMENT_LIST = { ( DATA_TYPE ~ ("," ~ DATA_TYPE)* )* }

// Definition of a probe
PROBE = {
	PROBE_KEY
	~ IDENTIFIER
	~ LEFT_PAREN
	~ ARGUMENT_LIST
	~ RIGHT_PAREN
	~ SEMICOLON
}

// Definition of a provider
PROVIDER = {
	PROVIDER_KEY
    ~ IDENTIFIER
    ~ LEFT_BRACE
    ~ (PROBE)+
    ~ RIGHT_BRACE
    ~ SEMICOLON
}

PRAGMA = ${
	"#pragma"
	~ SPACE+
	~ (!("\n") ~ ANY)*
	~ SPACE*
	~ "\n"
}

SPACE = _{ " " | "\t" }

// Files consist of providers and pragmas
FILE = {
	SOI
	~(
		PROVIDER
		| PRAGMA
	)*
	~EOI
}

WHITESPACE = _{ " " | "\t" | "\r" | "\n" }
COMMENT = _{ "/*" ~ (!"*/" ~ ANY)* ~ "*/" }