drawbridge 0.1.0

Drawbridge library.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108

{
  description = "Profian Drawbridge";

  inputs.cargo2nix.inputs.flake-compat.follows = "flake-compat";
  inputs.cargo2nix.inputs.flake-utils.follows = "flake-utils";
  inputs.cargo2nix.inputs.nixpkgs.follows = "nixpkgs";
  inputs.cargo2nix.inputs.rust-overlay.follows = "rust-overlay";
  inputs.cargo2nix.url = github:cargo2nix/cargo2nix;
  inputs.flake-compat.flake = false;
  inputs.flake-compat.url = github:edolstra/flake-compat;
  inputs.flake-utils.url = github:numtide/flake-utils;
  inputs.nixpkgs.url = github:profianinc/nixpkgs;
  inputs.rust-overlay.inputs.flake-utils.follows = "flake-utils";
  inputs.rust-overlay.inputs.nixpkgs.follows = "nixpkgs";
  inputs.rust-overlay.url = github:oxalica/rust-overlay;

  outputs = {
    self,
    cargo2nix,
    flake-utils,
    nixpkgs,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (
      system: let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [cargo2nix.overlays.default];
        };
        pkgsX86_64LinuxMusl = import nixpkgs {
          inherit system;
          crossSystem = {
            config = "x86_64-unknown-linux-musl";
          };
          overlays = [cargo2nix.overlays.default];
        };

        cargo2nixBin = cargo2nix.packages.${system}.cargo2nix;
        devRust = pkgs.rust-bin.fromRustupToolchainFile "${self}/rust-toolchain.toml";

        cargo.toml = builtins.fromTOML (builtins.readFile "${self}/Cargo.toml");

        mkBin = args: pkgs:
          ((pkgs.rustBuilder.makePackageSet ({
                packageFun = import "${self}/Cargo.nix";
                rustVersion = "1.61.0";
                workspaceSrc =
                  pkgs.nix-gitignore.gitignoreRecursiveSource [
                    "*.nix"
                    "*.yml"
                    "/.github"
                    "flake.lock"
                    "LICENSE"
                    "rust-toolchain.toml"
                  ]
                  self;
              }
              // args))
            .workspace
            ."${cargo.toml.package.name}" {})
          .bin;

        mkReleaseBin = mkBin {};

        nativeBin = mkReleaseBin pkgs;
        x86_64LinuxMuslBin = mkReleaseBin pkgsX86_64LinuxMusl;

        mkDebugBin = mkBin {release = false;};

        nativeDebugBin = mkDebugBin pkgs;
        x86_64LinuxMuslDebugBin = mkDebugBin pkgsX86_64LinuxMusl;

        buildImage = bin:
          pkgs.dockerTools.buildImage {
            inherit (cargo.toml.package) name;
            tag = cargo.toml.package.version;
            contents = [
              bin
            ];
            config.Cmd = [cargo.toml.package.name];
            config.Env = ["PATH=${bin}/bin"];
          };
      in {
        formatter = pkgs.alejandra;

        packages = {
          "${cargo.toml.package.name}" = nativeBin;
          "${cargo.toml.package.name}-x86_64-unknown-linux-musl" = x86_64LinuxMuslBin;
          "${cargo.toml.package.name}-x86_64-unknown-linux-musl-oci" = buildImage x86_64LinuxMuslBin;

          "${cargo.toml.package.name}-debug" = nativeDebugBin;
          "${cargo.toml.package.name}-debug-x86_64-unknown-linux-musl" = x86_64LinuxMuslDebugBin;
          "${cargo.toml.package.name}-debug-x86_64-unknown-linux-musl-oci" = buildImage x86_64LinuxMuslDebugBin;
        };
        packages.default = nativeBin;

        devShells.default = pkgs.mkShell {
          buildInputs = [
            pkgs.openssl

            cargo2nixBin

            devRust
          ];
        };
      }
    );
}