dora-cli 1.0.0-rc.2

`dora` goal is to be a low latency, composable, and distributed data flow.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110

cmake_minimum_required(VERSION 3.21)
project(cxx-dataflow LANGUAGES C)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_FLAGS "-fPIC")

set(DORA_ROOT_DIR "__DORA_PATH__" CACHE FILEPATH "Path to the root of dora")

set(dora_c_include_dir "${CMAKE_CURRENT_BINARY_DIR}/include/c")

# Map CMake's CMAKE_BUILD_TYPE to Cargo's profile so a Release build
# links against target/release/ and a Debug build (or no build type
# specified) links against target/debug/.
if(CMAKE_BUILD_TYPE STREQUAL "Debug" OR NOT CMAKE_BUILD_TYPE)
    set(dora_cargo_profile_dir "debug")
    set(dora_cargo_release_arg "")
else()
    set(dora_cargo_profile_dir "release")
    set(dora_cargo_release_arg "--release")
endif()

if(DORA_ROOT_DIR)
    include(ExternalProject)
    ExternalProject_Add(Dora
        SOURCE_DIR ${DORA_ROOT_DIR}
        BUILD_IN_SOURCE True
        CONFIGURE_COMMAND ""
        BUILD_COMMAND
            cargo build
            ${dora_cargo_release_arg}
            --package dora-node-api-c
        INSTALL_COMMAND ""
    )

    add_custom_command(OUTPUT ${dora_c_include_dir}
        WORKING_DIRECTORY ${DORA_ROOT_DIR}
        DEPENDS Dora
        COMMAND ${CMAKE_COMMAND} -E make_directory ${dora_c_include_dir}
        COMMAND ${CMAKE_COMMAND} -E copy_directory apis/c/node ${dora_c_include_dir}/node
    )

    add_custom_target(Dora_c DEPENDS ${dora_c_include_dir})
    set(dora_link_dirs ${DORA_ROOT_DIR}/target/${dora_cargo_profile_dir})
else()
    include(ExternalProject)
    ExternalProject_Add(Dora
        PREFIX ${CMAKE_CURRENT_BINARY_DIR}/dora
        GIT_REPOSITORY https://github.com/dora-rs/dora.git
        GIT_TAG main
        BUILD_IN_SOURCE True
        CONFIGURE_COMMAND ""
        BUILD_COMMAND
            cargo build
            ${dora_cargo_release_arg}
            --package dora-node-api-c
            --target-dir ${CMAKE_CURRENT_BINARY_DIR}/dora/src/Dora/target
        INSTALL_COMMAND ""
    )

    add_custom_command(OUTPUT ${dora_c_include_dir}
        WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/dora/src/Dora/target
        DEPENDS Dora
        COMMAND ${CMAKE_COMMAND} -E make_directory ${dora_c_include_dir}
        COMMAND ${CMAKE_COMMAND} -E copy_directory ../apis/c/node ${dora_c_include_dir}/node
    )

    set(dora_link_dirs ${CMAKE_CURRENT_BINARY_DIR}/dora/src/Dora/target/${dora_cargo_profile_dir})

    add_custom_target(Dora_c DEPENDS ${dora_c_include_dir})
endif()

link_directories(${dora_link_dirs})

# Platform-specific libraries the dora-node-api-c static archive needs:
# - Windows: standard winsock + crypto/user libraries
# - macOS: Apple frameworks pulled by transitive Rust deps (chrono time
#   zones via CoreFoundation; TLS / network config via Security +
#   SystemConfiguration). Without these the link fails with missing
#   _CF* / _Sec* symbols.
# - Other Unix: libm + libz
if(WIN32)
    set(dora_platform_libs ws2_32 userenv ntdll bcrypt)
elseif(APPLE)
    set(dora_platform_libs
        m
        z
        "-framework CoreFoundation"
        "-framework Security"
        "-framework SystemConfiguration"
    )
else()
    set(dora_platform_libs m z)
endif()

add_executable(talker_1 talker_1/node.c)
add_dependencies(talker_1 Dora_c)
target_include_directories(talker_1 PRIVATE ${dora_c_include_dir})
target_link_libraries(talker_1 dora_node_api_c ${dora_platform_libs})

add_executable(talker_2 talker_2/node.c)
add_dependencies(talker_2 Dora_c)
target_include_directories(talker_2 PRIVATE ${dora_c_include_dir})
target_link_libraries(talker_2 dora_node_api_c ${dora_platform_libs})

add_executable(listener_1 listener_1/node.c)
add_dependencies(listener_1 Dora_c)
target_include_directories(listener_1 PRIVATE ${dora_c_include_dir})
target_link_libraries(listener_1 dora_node_api_c ${dora_platform_libs})

install(TARGETS listener_1 talker_1 talker_2 DESTINATION ${CMAKE_CURRENT_SOURCE_DIR}/bin)