dirge-agent 0.18.6

Minimalistic coding agent written in Rust, optimized for memory footprint and performance
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

{
  lib,
  stdenv,
  rustPlatform,
  cmake,
  mold,
  src,
}:

let
  # The flake passes `src = self`; use path literals for lib.fileset because
  # flake `self.outPath` is string-like and filesets require paths.
  cargoToml = lib.importTOML ../Cargo.toml;
  source = lib.fileset.toSource {
    root = ../.;
    fileset = lib.fileset.unions [
      ../Cargo.toml
      ../Cargo.lock
      ../build.rs
      ../src
      ../prompts
      ../plugins
    ];
  };
in
rustPlatform.buildRustPackage {
  pname = "dirge";
  version = cargoToml.package.version;

  src = source;

  cargoLock.lockFile = ../Cargo.lock;

  nativeBuildInputs = [
    cmake
    # evil-janet generates bindings during the build; bindgenHook also
    # provides clang on PATH for .cargo/config.toml's linker setting.
    rustPlatform.bindgenHook
  ]
  ++ lib.optionals stdenv.isLinux [ mold ];

  # Tests reach network/LLM providers and can exceed build timeouts.
  doCheck = false;

  meta = {
    description = "Minimal, fast pure-Rust coding agent with persistent memory";
    homepage = "https://github.com/dirge-code/dirge";
    license = lib.licenses.gpl3Only;
    mainProgram = "dirge";
    platforms = [
      "x86_64-linux"
      "aarch64-linux"
      "aarch64-darwin"
    ];
  };
}