deb 0.5.20

Utilities for working with files and formats commonly found when working with Debian's project tooling, or infrastructure.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

alpha = { 'a'..'z' | 'A'..'Z' }
digit = { '0'..'9' }
whitespace = { (" " | "\t" | "\n")+ }

package_name = { (alpha | digit | "-" | "_" | "." | "+")+ }

build_profile_name = { (alpha | digit | "-" | "_" | "." | "+")+ }
build_profile_constraint = { not? ~ whitespace* ~ build_profile_name }
build_profile_constraints = {
  "<" ~
    whitespace* ~
    build_profile_constraint ~
    (
      whitespace* ~
      build_profile_constraint ~
      whitespace*
    )* ~
    whitespace* ~
  ">"
}

build_profile_restriction_formula = {
    (whitespace* ~ build_profile_constraints ~ whitespace*)*
}

not = { "!" }

arch_name = { (alpha | digit | "-")+ }
arch_constraint = { not? ~ arch_name }
arch_constraints = {
  "[" ~ arch_constraint ~ (whitespace* ~ arch_constraint ~ whitespace*)* ~ "]"
}

version = {
  (alpha | digit | "." | "+" | "~" | "-" | ":")+
}

version_operator = {
    "==" | "=" |
    ">=" | ">>" |
    "<=" | "<<"
}

version_constraint = {
  "("
    ~ whitespace* ~
    version_operator
    ~ whitespace* ~
    version
    ~ whitespace* ~
  ")"
}

package = {
  whitespace* ~
  package_name ~ (":" ~ arch_name)? ~
  whitespace* ~
  (
    whitespace* ~
    (
      version_constraint | arch_constraints | build_profile_constraints
    ) ~
    whitespace*
  )* ~
  whitespace*
}

relation = {
  whitespace* ~
  package ~ (whitespace* ~ "|" ~ whitespace* ~ package)*
}

dependency = {
    SOI ~
    (
      relation ~
      (
        whitespace* ~ "," ~ whitespace* ~
        relation
      )*
    )? ~
    EOI
}