datachannel-sys 0.23.0+0.23.2

Native bindings to libdatachannel.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

#[=======================================================================[.rst
Findplog
----------

FindModule for Plog library

Imported Targets
^^^^^^^^^^^^^^^^

This module defines the :prop_tgt:`IMPORTED` target ``plog::plog``.

Result Variables
^^^^^^^^^^^^^^^^

This module sets the following variables:

``plog_FOUND``
  True, if the library was found.

Cache variables
^^^^^^^^^^^^^^^

The following cache variables may also be set:

``plog_INCLUDE_DIR``
  Directory containing ``plog/Log.h``.

#]=======================================================================]

include(FindPackageHandleStandardArgs)

find_path(
  plog_INCLUDE_DIR
  NAMES plog/Log.h
  PATHS /usr/include /usr/local/include)

find_package_handle_standard_args(
  plog
  REQUIRED_VARS plog_INCLUDE_DIR)
mark_as_advanced(plog_INCLUDE_DIR)

if(plog_FOUND)
  if(NOT TARGET plog::plog)
    add_library(plog::plog INTERFACE IMPORTED)
    set_target_properties(plog::plog PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${plog_INCLUDE_DIR}")
  endif()
endif()