context-notation 0.1.4

Featherweight semantic notation for text
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

/*
    Public slashlink:
    @public/foo/bar

    Private slashlink:
    /foo/bar
*/

Context = { SOI ~ (Block*) ~ EOI }

Slug      = @{ (LETTER | NUMBER | SlugSpecialCharacter)+ }
Petname   = @{ (!"/" ~ Bridge | LETTER | NUMBER)+ }
Protocol  = @{ "http" ~ "s"? ~ "://" }
HyperLink = @{ Protocol ~ (!(Whitespace | ("." ~ Whitespace)) ~ ANY)+ }

BridgeCharacter       = _{ "-" | "_" | "." }
Bridge                = _{ BridgeCharacter ~ !(" " | BridgeCharacter | LeadingInlineBoundary | Terminator | EOI) }
SlugSpecialCharacter  = _{ Bridge | "/" ~ !"/" }
Whitespace            = _{ (SEPARATOR+ | Terminator) }
Indentation           = _{ SPACE_SEPARATOR ~ SPACE_SEPARATOR }
Terminator            = _{ NEWLINE | IgnoredUnicode }
IgnoredUnicode        = _{ '\u{1FF80}'..'\u{10FFFF}' }
Contiguous            = _{ !NEWLINE ~ ANY }
MentionBoundary       = _{ "@" }
SlashLinkBoundary     = _{ "/" ~ !"/" }
HashTagBoundary       = _{ "#" }
InlineCodeBoundary    = _{ !"\\" ~ "`" }
WikiLinkOpenBoundary  = _{ "[[" ~ !"[" }
WikiLinkCloseBoundary = _{ "]]" }
ListItemBoundary      = _{ "- " }
QuoteBoundary         = _{ "> " }
CodeBoundary          = _{ "```" }
LeadingInlineBoundary = _{ MentionBoundary | SlashLinkBoundary | HashTagBoundary | InlineCodeBoundary }
TextCharacter         = _{ !Whitespace ~ Contiguous ~ LeadingInlineBoundary | !NonTextSpan ~ Contiguous }
Span                  = _{ NonTextSpan | Text }
NonTextSpan           = _{ HyperLink | InlineCode | HashTag | SlashLink | WikiLink | Mention }
BlockContent          = _{ Span+ }
Block                 = _{ List | Quote | Code | Paragraph | Empty }

Mention         = { MentionBoundary ~ Petname }
SlashLink       = { Mention? ~ SlashLinkBoundary ~ Slug }
HashTag         = { HashTagBoundary ~ Slug }
Text            = { TextCharacter+ }
Empty           = { NEWLINE }
InlineCode      = {
    InlineCodeBoundary ~ InlineCodeValue ~ InlineCodeBoundary
}
InlineCodeValue = { (!InlineCodeBoundary ~ Contiguous)+ }

WikiLink        = { WikiLinkOpenBoundary ~ WikiLinkValue ~ WikiLinkCloseBoundary }
WikiLinkValue   = { (!WikiLinkOpenBoundary ~ !WikiLinkCloseBoundary ~ Contiguous)+ }
Paragraph       = { BlockContent ~ NEWLINE? }
Code            = {
    CodeBoundary ~ Slug? ~ NEWLINE ~ CodeValue? ~ CodeBoundary ~ NEWLINE?
}
CodeValue       = { (!CodeBoundary ~ ANY)* ~ NEWLINE? }
List            = {
    ListIndentation ~ ListItem ~ (NEWLINE? ~ PEEK_ALL ~ ListItem)* ~ NEWLINE?
}
NestedList      = {
    ListIndentation ~ ListItem ~ (NEWLINE? ~ PEEK_ALL ~ ListItem)*
}
ListIndentation = { PUSH(Indentation*) }
ListItem        = {
    ListItemBoundary ~ ListItemContent ~ (NEWLINE ~ (&(PEEK_ALL ~ Indentation+) ~ NestedList ~ DROP))*
}
ListItemContent = { BlockContent }
Quote           = { QuoteLine ~ (NEWLINE ~ QuoteLine)* ~ NEWLINE? }
QuoteLine       = { QuoteBoundary ~ BlockContent }