codeberg-cli 0.5.5

CLI Tool for codeberg similar to gh and glab
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125

{ inputs, ... }:
{

  flake.homeModules = rec {
    default = berg;
    berg =
      {
        config,
        lib,
        pkgs,
        ...
      }:
      let
        tomlFormat = pkgs.formats.toml { };
        cfg = config.programs.berg;
      in
      {

        options.programs.berg = {
          enable = lib.mkEnableOption "codeberg-cli";
          package = lib.mkPackageOption inputs.self.packages.${pkgs.stdenv.system} "berg" { };
          settings = lib.mkOption {
            description = ''
              Configuration values for the cli.

              See `berg config info` for all possible values.
            '';
            type = lib.types.submodule {
              options = {
                base_url = lib.mkOption {
                  type = lib.types.str;
                  default = "codeberg.org";
                };
                editor = lib.mkOption {
                  type = lib.types.str;
                  default = "nvim";
                };
                enable_https = (lib.mkEnableOption "use https") // {
                  default = true;
                };
                fancy_tables = (lib.mkEnableOption "use fancy CLI tables") // {
                  default = true;
                };
                max_width = lib.mkOption {
                  type = lib.types.int;
                  default = 200;
                };
                no_color = (lib.mkEnableOption "use no colors in the CLI") // {
                  default = true;
                };
              };
            };
            default = { };
          };

        };

        config = lib.mkIf cfg.enable {

          home.packages = [
            cfg.package
          ];

          home.file.".config/berg-cli/berg.toml" = {
            enable = cfg.settings != { };
            source = tomlFormat.generate "berg.toml" cfg.settings;
          };

        };

      };
  };

  perSystem =
    {
      pkgs,
      ...
    }:
    let
      home-manager = builtins.getFlake "github:nix-community/home-manager/929535c3082afdf0b18afec5ea1ef14d7689ff1c";
    in
    {
      checks = {
        home-manager-berg = pkgs.testers.runNixOSTest {
          name = "home-manager-tests-work";
          nodes.machine =
            { ... }:
            {
              imports = [ home-manager.nixosModules.home-manager ];

              users.users.alice = {
                isNormalUser = true;
                initialPassword = "alice";
              };

              home-manager.users.alice = {
                imports = [ inputs.self.homeModules.berg ];

                programs.berg = {
                  enable = true;
                  settings = {
                    editor = "nvim";
                    max_width = 100;
                  };
                };

                home.stateVersion = "25.05";
              };
            };
          testScript = ''
            machine.start()
            machine.wait_for_unit("multi-user.target")
            machine.succeed("su - alice -c 'berg --help'")
            config = machine.succeed("su - alice -c 'berg config info'")

            print(config)
            assert ".config/berg-cli/berg.toml" in config, "home manager config isn't in use"
            assert "nvim" in config, "home manager sets nvim as editor"
            assert "100" in config, "home manager sets 100 as max width"
          '';
        };
      };
    };

}